错误的参数数量或类型，PL/SQL 中的错误

Question

我必须创建一个 RECORD 列表，我需要将它发送到一个过程。

有我的header.

CREATE OR REPLACE PACKAGE tema4 IS
 TYPE obj IS RECORD(id INTEGER := 0,percent INTEGER := 0);
 TYPE listObj IS TABLE OF obj INDEX BY PLS_INTEGER;
 PROCEDURE ex1 (p_listObj IN listObj);
END tema4;

我的body.

create or replace PACKAGE BODY tema4 IS
PROCEDURE ex1 (p_listObj IN listObj) IS
BEGIN
 DBMS_OUTPUT.PUT_LINE('Cant reach');
END ex1;
END tema4;

还有我调用过程 ex1 的代码。

DECLARE
 TYPE obj IS RECORD(id INTEGER := 0,percent INTEGER := 0);
 TYPE listObj IS TABLE OF obj INDEX BY PLS_INTEGER;
 v_obj obj;
 v_listObj listObj;
BEGIN
 FOR v_i IN (SELECT ID,BURSA FROM STUDENTI ORDER BY ID) LOOP
  v_obj.id := v_i.id;
  v_obj.percent := 50;
  v_listObj(v_i.id) := v_obj;
 END LOOP;
 FOR v_i IN v_listObj.FIRST..v_listObj.LAST LOOP
  DBMS_OUTPUT.PUT_LINE(v_listObj(v_i).id || ' - ' || 
  v_listObj(v_i).percent);
 END LOOP;
 tema4.ex1(v_listObj); --this line is with problems
END;

PLS-00306: wrong number or types of arguments in call to 'EX1'

有人可以解释一下我的代码有什么问题吗？我还尝试将我的类型创建为全局类型，但由于 'RECORD' 关键字，它不会让我这样做。

Answer 1

不要再次声明类型（新类型），使用已经在包规范中声明的类型：

DECLARE
 v_obj tema4.obj;
 v_listObj tema4.listObj;
BEGIN
 FOR v_i IN (SELECT ID,BURSA FROM STUDENTI ORDER BY ID) LOOP
  v_obj.id := v_i.id;
  v_obj.percent := 50;
  v_listObj(v_i.id) := v_obj;
 END LOOP;
 FOR v_i IN v_listObj.FIRST..v_listObj.LAST LOOP
  DBMS_OUTPUT.PUT_LINE(v_listObj(v_i).id || ' - ' || 
  v_listObj(v_i).percent);
 END LOOP;
 tema4.ex1(v_listObj); --this line is with problems
END;

错误的参数数量或类型，PL/SQL 中的错误

Wrong number or TYPES of arguments, error in PL/SQL

oracle

types

plsql

record

plsqldeveloper