除了 X Y 坐标，我如何查看导入的 shapefile 中存在的其他 values/information

Question

我将一个 shapefile 加载到 NetLogo 中。称为 "locations"。我可以在指挥中心查看 XY 坐标。但是，我想查看每个 coordinate.I 的 OBJECTID（存在于 shapefile 中）需要此信息以供参考。我该怎么做才能查看 shapefile 中每条线要素的 OBJECTID？

Answer 1

在此示例设置中，"Sector_Boundary.shp" 是一个包含 10 个子单元的 shapefile：

extensions [ gis ]
globals [ example-gis-data ]

to setup
  ca
  set example-gis-data gis:load-dataset "Sector_Boundary.shp"
  gis:set-drawing-color white
  gis:draw example-gis-data 1
  reset-ticks  
end

如果您实际上只需要输出对象 ID，则可以使用 gis:feature-list-of 拉取功能列表，然后使用 gis:property-value 拉取每个功能的 "OBJECTID"：

to view-info
  let list-of-features gis:feature-list-of example-gis-data
  let list-of-ids map [ i -> gis:property-value i "OBJECTID" ] list-of-features
  print list-of-ids
end

当然你可以根据需要对不同的属性名字做同样的事情，并根据需要输出其他参考信息。例如，如果您的位置 shapefile 像我的 "Sector_Boundary.shp" 一样有一个 NAME 字段，您可以这样做：

to view-info
  let list-of-features gis:feature-list-of example-gis-data
  let list-of-ids map [ i -> gis:property-value i "OBJECTID" ] list-of-features
  let list-of-names map [ i -> gis:property-value i "NAME" ] list-of-features
  ( foreach list-of-names list-of-ids [
    [ name id ] ->
    print ( word "Name: " name ", Object id: " id )
  ])  
end

查看与每个对象 ID 关联的名称。

除了 X Y 坐标，我如何查看导入的 shapefile 中存在的其他 values/information

Other than X Y coordinates ,how can I view other values/information present in an imported shapefile

shapefile

netlogo