"our"或"use vars"中有什么魔法满足"use strict qw(vars)"？

Question

我有工作代码，但我想了解为什么它能工作。我也在尝试了解更多有关 Perl 5 内部的信息（perlbrew、perl-5.26.1、Cygwin x64）。

我从 perlvar and strict 得知 use strict 'vars' 通过在 $^H 中设置标志来工作。 Perl 然后根据这些标志测试对非 :: 变量的访问。不知何故，our 和 use vars 都会标记变量，以便它们通过测试。他们是怎么做到的？

例如：

perl -E 'package Foo;
    use strict "vars";
    use vars qw($foo);
    say $foo;'

运行良好（尽管它没有产生任何输出）。基于the source for use vars，我尝试了这个，我认为会有同样的效果：

perl -E 'package Foo;
    use strict "vars";
    my $sym = "Foo::foo";          # <-- These two lines pulled straight
    *$sym = $$sym;                # <-- from the source for the vars pragma
    say $foo;'

然而，它给了我一个错误：Global symbol "$foo" requires explicit package name。我也试过上面的$sym = "::Foo:foo"，结果一样。

查了一下，$Foo::foo在符号table:

$ perl -E 'package Foo;
      use Data::Dumper;
      use strict "vars"; 
      my $sym = "Foo::foo";
      *$sym = $$sym; 
      say Dumper(\%{"Foo::"});'    # <-- Foo's symbol table

Output: 
$VAR1 = {
    'BEGIN'  => *Foo::BEGIN,
    'Dumper' => *Foo::Dumper,
    'foo'    => *Foo::foo          # <-- yep, it's there
};

use vars 还有什么我想念的？ our 做的是相同的还是不同的？

更新

这是基于的A/B：

Fails                         Succeeds
-------------------------     ----------------------------------
package Foo;                  package Foo;
use strict "vars";            use strict "vars";

                              BEGIN {
                                  package Bar;
my $sym="Foo::foo";               my $sym = "Foo::foo";
*$sym = $$sym;                   *$sym = $$sym;
                              }
say $foo;                     say $foo;

Answer 1

use strict 'vars' works by setting flags in $^H.

是的，但这是一个实现细节。 $^H 公开了一些内部解释器状态位，但您不应该在普通代码中触及它。

Somehow, both our and use vars mark variables so that they will pass the test. How do they do so?

这也被视为实现细节。

但是，我们可以深入了解一下。 strict "vars" 抱怨未声明的变量（在编译时）。

存在免于此检查的硬编码变量列表；它包括所有标点变量（例如 $/、$_ 等，以及 $a 和 $b（由 sort 使用））。

所有词法（即局部）声明的变量也通过strict；这就是 my、our 和 state 的工作原理。（出于我们的目的，local 不是声明，也不会创建局部变量；local 临时更改现有变量的值。）

第三个例外是从模块导出的变量。使用全局变量作为模块接口的一部分通常被认为是一个坏主意，但一些较旧的模块仍然这样做。 English 也导出变量，因为这是它的重点，所以我们将以它为例：

use strict;
use English qw($INPUT_RECORD_SEPARATOR);
$INPUT_RECORD_SEPARATOR = "";  # <--
my $paragraph = readline STDIN;

标记为 <-- 的行不会抛出错误，因为 Perl 会记住哪些变量是从模块导入的。

"exporting" 究竟是什么意思？它只是意味着跨包边界对符号进行别名：

*main::foo = $Some::Module::foo;  # now $main::foo is an alias for $Some::Module::foo

奇怪的是，就 Perl 内部结构而言，如果变量在其他包中被别名化，则它是 "imported"。它的别名是什么并不重要 to;重要的是别名发生的地方。 use vars (ab-) 使用此细节通过将您自己的变量导出回您来绕过 strict "vars"：

package Some::Package;
use vars qw($foo);

像

一样工作

package Some::Package;
BEGIN {
    package vars;
    *Some::Package::foo = $Some::Package::foo;
}
# now $foo is an alias to ... itself

另一个难题是 use 发生在编译时，就像 BEGIN 块一样。你的例子失败了，因为你的别名尝试只发生在运行时，这对 strict 来说太晚了，而且因为它没有切换到不同的包来做别名。

最后 vars 只是一个模块，用纯 Perl 编写。 our 不同：它是一个真正的关键字，是语言的一部分。它也有不同的行为：它有效地创建了一个别名（到包变量），但该别名存在于本地范围内，而不是符号 table.

考虑例如以下：

my $foo = 2;
{
    our $foo = "hello";
    print "foo = $foo; main::foo = $main::foo\n";
}
print "foo = $foo; main::foo = $main::foo\n";

这输出

foo = hello; main::foo = hello
foo = 2; main::foo = hello

因为内部 our $foo 声明隐藏了内部块中的外部 $foo。在块中，$foo 和 $main::foo 都引用同一个变量；外部 $foo 指的是词法 my $foo，它未被触及。

与use vars的另一个区别：

use strict;
package Foo;
our $x = "hello";
package Bar;
print "$x\n";  # hello

此代码工作正常，因为 package 声明不会创建新范围。这里只有一个作用域单元（整个文件），因此 our $x 使 $x 引用 $Foo::x 文件的其余部分，无论您切换到哪个包。

另一方面：

use strict;
package Foo;
use vars qw($x);
$x = "hello";
package Bar;
print "$x\n";

此代码甚至无法编译。最后一行中对 $x 的引用无法解析：Perl 首先检查本地作用域，但没有本地声明的 $x。然后它检查当前包 (Bar) 也没有找到任何东西，如果没有 strict "vars" 它会自动为你创建 $Bar::x，但是启用 strict "vars" 这只是一个错误。 $Foo::x 无关紧要，从未检查过。

"our"或"use vars"中有什么魔法满足"use strict qw(vars)"？

What magic in "our" or "use vars" satisfies "use strict qw(vars)"?

perl

packages

scoping

variable-declaration

language-lawyer

更新