如何在 Haskell 中最多组合解析器 n 次？

Question

我正在尝试在 Haskell 中组合解析器，以便我最多可以解析某些模式 n 次。为了说明这一点，假设我想从输入中解析最多八位数字。我知道我可以使用 Text.Parser.Combinators 中的 count 来准确解析 n 次出现，例如：

import Text.Parser.Char        (digit)
import Text.Parser.Combinators (count)

eightDigits :: Parser [Char]
eightDigits = count 8 digit

但是，如果找不到恰好 8 位数字，此操作将失败。我还可以使用 some 来解析一位或多位数字：

import Text.Parser.Char        (digit)
import Text.Parser.Combinators (some)

someDigits :: Parser [Char]
someDigits = some digit

上面的问题是它可能消耗了比我想要的更多的数字。最后，我可以使用 try，它结合了可能消耗输入的解析器，并在失败时返回到它开始的地方：

import Text.Parser.Char        (digit)
import Text.Parser.Combinators (count, try)
import Control.Applicative     ((<|>))

twoOrThreeDigits :: Parser [Char]
twoOrThreeDigits = try (count 3 digit) <|> count 2 digit

虽然这可以扩展到最多 8 次重复，但它不可扩展也不优雅，所以问题是我如何组合解析器来解析 1 到最多 n 次之间的任何模式？

Answer 1

您可以构造一个类似 many 的组合器，其上限为：

upto :: Int -> Parser a -> Parser [a]
upto n p | n > 0 = (:) <$> try p <*> upto (n-1) p <|> return []
upto _ _ = return []

对于 1 到 n，一个类似于 many1 的组合器：

upto1 :: Int -> Parser a -> Parser [a]
upto1 n p | n > 0 = (:) <$> p <*> upto (n-1) p
upto1 _ _ = return []

一个简短的演示：

> map (parse (upto 8 digitChar) "") ["", "123", "1234567890"]
[Right "",Right "123",Right "12345678"]

如何在 Haskell 中最多组合解析器 n 次？

How to combine parsers up to n times in Haskell?

parsing

haskell

parsec

parser-combinators

trifecta