如何像下面解释的那样统一创建着色器？

Question

我想创建一个统一的着色器，漫反射纹理将如图所示应用于平面。

现在我可以在平面上将纹理分成四个部分，如下所示

使用此代码

Shader "Custom/bookshader" {
Properties {
    _Color ("Color", Color) = (1,1,1,1)
    _MainTex ("Albedo (RGB)", 2D) = "white" {}
    _Glossiness ("Smoothness", Range(0,1)) = 0.5
    _Metallic ("Metallic", Range(0,1)) = 0.0
}
SubShader {
    Tags { "RenderType"="Opaque" }
    LOD 200

    CGPROGRAM
    // Physically based Standard lighting model, and enable shadows on all light types
    #pragma surface surf Standard fullforwardshadows

    // Use shader model 3.0 target, to get nicer looking lighting
    #pragma target 3.0

    sampler2D _MainTex;

    struct Input {
        float2 uv_MainTex;
    };

    half _Glossiness;
    half _Metallic;
    fixed4 _Color;

    // Add instancing support for this shader. You need to check 'Enable Instancing' on materials that use the shader.
    // See https://docs.unity3d.com/Manual/GPUInstancing.html for more information about instancing.
    // #pragma instancing_options assumeuniformscaling
    UNITY_INSTANCING_CBUFFER_START(Props)
        // put more per-instance properties here
    UNITY_INSTANCING_CBUFFER_END

    void surf (Input IN, inout SurfaceOutputStandard o) {
        // Albedo comes from a texture tinted by color
        fixed4 c = tex2D (_MainTex, float2(IN.uv_MainTex.x*2, IN.uv_MainTex.y*2)) * _Color;
        o.Albedo = c.rgb;
        // Metallic and smoothness come from slider variables
        o.Metallic = _Metallic;
        o.Smoothness = _Glossiness;
        o.Alpha = c.a;
    }
    ENDCG
}
FallBack "Diffuse"
}

Answer 1

Shader "Unlit/Mirror"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                return o;
            }

            fixed GetMask(fixed2 uv){
            return step(uv.x,0)*step(uv.y,0);
            }

            fixed4 frag (v2f i) : SV_Target
            {
                fixed2 uv = (i.uv*2.0+-1.0).rg;

                fixed UpRight = GetMask(float2(uv.x,uv.y));
                fixed UpLeft =  GetMask(float2(-uv.x,uv.y));

                fixed DownLeft =  GetMask(float2(-uv.x,-uv.y));
                fixed DownRight = GetMask(float2(uv.x,-uv.y));

                // sample the texture
                fixed4 UpRightTex = tex2D(_MainTex, float2(uv.x,uv.y))*UpRight;
                fixed4 UpLeftTex = tex2D(_MainTex, float2(-uv.x,uv.y))*UpLeft;
                fixed4 DownLeftTex = tex2D(_MainTex, float2(-uv.x,-uv.y))*DownLeft;
                fixed4 DownRightTex = tex2D(_MainTex, float2(uv.x,-uv.y))*DownRight;

                fixed4 result = max(max(UpRightTex,UpLeftTex),max(DownLeftTex,DownRightTex));

                return result;
            }
            ENDCG
        }
    }
}

如何像下面解释的那样统一创建着色器？

How do I create a shader in unity like explained below?

shader

hlsl

unity3d