计算在日期范围 Excel 内成功联系的不同人员的数量

Question

下午好，

我有一个大数据 table，其中包含尝试联系客户的帐户。每个条目都标有：

一个。客户名称 b.尝试联系的日期 C。联系尝试是否成功 (S) 或失败 (U)

这是数据示例，已替换机密名称

我需要计算每个月成功联系的不同人的数量，并将其显示在 table 中，如下所示：

请注意，我不想计算成功联系他们的次数，只要他们至少联系过一次即可。

我试过以下公式：

{=SUMPRODUCT(IF((EncounterDate<=DU4)*(EncounterDate>=DT4), 
1/COUNTIFS(EncounterDate, "<="&DU4, EncounterDate, ">="&DT4, 
EncLastFirstName, EncLastFirstName, CMService, "S"), 0))}

DU4 - 月末日期
DT4 - 每月的第一天

这个公式出现 Div/0 错误。知道我做错了什么，或者我应该做什么吗？

谢谢，非常感谢！

Answer 1

也许问题在于您只是检查了日期，然后假设至少有一个成功的联系。有些人可能只有不成功的尝试，所以你除以 0。

Answer 2

您得到 #DIV/0! 因为除法的分母可以为零，公式 'short circuit' 出现第一个未处理的错误。如果任何行的结果为零，

COUNTIFS(EncounterDate, "<="&DU4, EncounterDate, ">="&DT4, EncLastFirstName, EncLastFirstName, CMService, "S")

...然后你得到 #DIV/0! 和 1/COUNTIFS(...).

我的解决方案是删除 IF 部分并将每个条件收集到一个分子中，如果全部为真则解析为 1，如果为假则解析为 0。此外，将标准分子的倒数加到除法运算的分母上；例如如果 (CMService="S") 在分子中，则将 (CMService<>"S") 添加到分母中。在这些情况下，分母将不为零，分子将为零。零除以任何值仍然为零（例如 0/100 == 0），因此分母是什么并不重要，您永远不会得到 #DIV/0! 错误。

如果分子和countifs中的所有条件都为真，则分子为1，分母没有添加任何内容。如果分子和 countifs 中的任何条件为假，则分子为 0 并且已将某些内容添加到分母以确保不会出现 #DIV/0!。

在 DV4 中作为标准公式没有 CSE，

             [<~~~~~~~~~~~~~~~~~ numerator portion ~~~~~~~~~~~~~~~~~>] / [<~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ denominator portion ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~>]+[<~~~~~~~~~~ denominator adjustment portion ~~~~~~~~~~>]
=sumproduct(((EncounterDate>=DT4)*(EncounterDate<=DU4)*(CMService="S"))/(countifs(EncLastFirstName, EncLastFirstName, EncounterDate, ">="&DT4, EncounterDate, "<="&DU4, CMService, "S")+(EncounterDate<DT4)+(EncounterDate>DU4)+(CMService<>"S")))

通过这种用基础数学抵消任何 #DIV/0! 的方法，您可以增加或减少标准的数量，只要您保持分母调整为分子的倒数即可。

顺便说一句，你问题中的预期结果是错误的。

计算在日期范围 Excel 内成功联系的不同人员的数量

Counting number of distinct people successfully contacted in a date range Excel

excel

excel-formula

count-unique