GraphDB 免费版中未显示域范围图。 8.5

Question

我将以下语句加载到 OWL-Horst 存储库中：

@prefix : <http://example.org/owlim#>.
@prefix owl: <http://www.w3.org/2002/07/owl#> .
@prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#> .

:Foo a owl:Class .
:Bar a owl:Class .
:p a owl:ObjectProperty .
:f a :Foo .
:b a :Bar .
:f :p :b .

但我无法想象 Domain-Range chart。我收到消息“''没有可用的域范围图。

我的图表有什么问题？

Answer 1

[a :Foo] :p [a :Bar] 不包含 :p rdfs:domain :Foo; rdfs:range :Bar。这应该是RDFS级别的规则，there is no这样的规则。

你应该明确地说：

:p rdfs:domain :Foo .
:p rdfs:range :Bar .

然后你会得到这样的东西image。

顺便说一句，构建域范围图，GraphDB 执行以下查询：

SELECT DISTINCT ?prop ?propertyType ?objectPropClass (?c != :Bar as ?implicit) {
    {
        :Bar rdfs:subClassOf ?c
    }
    UNION
    {
        VALUES ?c { :Bar }
    }
    {
        ?prop a owl:ObjectProperty ;
            rdfs:domain ?c ;
            rdfs:range ?objectPropClass ;
            rdfs:domain ?objectPropClass ;
            rdfs:range ?c .
        BIND ("objectLeftRight" as ?propertyType)
        BIND (1 as ?order)
    }
    UNION
    {
        ?prop a owl:ObjectProperty ;
            rdfs:domain ?c ;
            rdfs:range ?objectPropClass .
        BIND ("objectRight" as ?propertyType)
        BIND (2 as ?order)
    }
    UNION
    {
        ?prop a owl:DatatypeProperty ;
            rdfs:domain ?c .
        BIND ("datatype" as ?propertyType)
        BIND (3 as ?order)
    }
    UNION
    {
        ?prop a owl:ObjectProperty ;
            rdfs:domain ?objectPropClass ;
            rdfs:range ?c .
        BIND ("objectLeft" as ?propertyType)
        BIND (4 as ?order)
    }
    FILTER(?objectPropClass != :Bar || ?propertyType != "objectRight"
                                    && ?propertyType != "objectLeft")
} ORDER BY ?order ?objectPropClass ?prop

更新

...after taking a quick look at the docs, I believed that GraphDB did a kind of analysis based on the actual use of the properties with classes instances.

看来 Class relationships 视图在左侧面板中提供了此类信息。
此外，您还可以创建 your own Visual Graph 配置。我能够 CONSTRUCT 这张图片：

GraphDB 免费版中未显示域范围图。 8.5

Domain-Range graph not displayed in GraphDB Free ver. 8.5

rdf

rdfs

graphdb