如何将元素的所有内容与 XSLT 匹配？

Question

我有一个 XML 文件，其中包含一些转义的 XHTML，如下所示：

<AuthorBio>
 <p>Paragraph with<br/>forced line break.</p>
</AuthorBio>

我正在尝试使用 XSLT 将其转换为以下内容：

<ParagraphStyleRange>
 <CharacterStyleRange>
  <Content>
   Paragraph with&#x2028;forced line break.
  </Content>
 </CharacterStyleRange>
 <Br/>
</ParagraphStyleRange>

这是我的 XSLT 的简化版本：

<xsl:template match="AuthorBio"> 
 <xsl:for-each select="p">
  <ParagraphStyleRange>
   <xsl:apply-templates select="./node()"/>
   <Br/>
  </ParagraphStyleRange>
 </xsl:for-each>
</xsl:template>

<xsl:template match="AuthorBio/p/text()">
 <CharacterStyleRange>
   <Content><xsl:value-of select="."/></Content>
  </CharacterStyleRange> 
</xsl:template>

<xsl:template match="br">
 &#x2028;
</xsl:template>

不幸的是，这给了我以下结果：

<ParagraphStyleRange>
 <CharacterStyleRange>
  <Content>
   Paragraph with
  </Content>
 </CharacterStyleRange>
 &#x2028;
 <CharacterStyleRange>
  <Content>
   forced line break.
  </Content>
 </CharacterStyleRange>
 <Br/>
</ParagraphStyleRange>

我意识到这是因为我的模板匹配 p/text()，因此在 <br/> 处中断。但是——除非我以完全错误的方式处理这个问题——我想不出一种方法来 select 元素的全部内容，包括所有子节点。类似于 copy-of，我想，除了删除包装元素。这可能吗？有没有办法匹配节点的全部内容，而不是节点本身？或者有更好的方法来解决这个问题吗？

Answer 1

您似乎只想为每个段落输出一次 CharacterStyleRange 和 Content 元素。如果是这样，将当前匹配 AuthorBio/p/text() 的模板更改为仅匹配 p，并在其中输出 ParagraphStyleRange、CharacterStyleRange 和 Content。

试试这个 XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="xml" indent="yes" />

    <xsl:template match="AuthorBio"> 
        <xsl:apply-templates select="p" />
    </xsl:template>

    <xsl:template match="p">
        <ParagraphStyleRange>
            <CharacterStyleRange>
                <Content>
                    <xsl:apply-templates />
                </Content>
            </CharacterStyleRange> 
            <Br/>
        </ParagraphStyleRange>
    </xsl:template>

    <xsl:template match="br">
        <xsl:text>&#x2028;</xsl:text>
    </xsl:template>
</xsl:stylesheet>

如何将元素的所有内容与 XSLT 匹配？

How do I match all of an element's content with a XSLT?

xml

xslt