vb.net 如何在 dropdownclosed 事件后覆盖组合框中的文本

Question

我创建这段代码来说明这个想法，它使用了一个组合框和一个文本框

Private Sub ComboBox2_DropDown(sender As Object, e As EventArgs) Handles ComboBox2.DropDown
    ComboBox2.Items.Clear()
    ComboBox2.Items.Add("0001 | Apple")
    ComboBox2.Items.Add("0002 | Pear")
    ComboBox2.Items.Add("0003 | Banana")
    ComboBox2.Items.Add("0004 | Pineapple")
    ComboBox2.Items.Add("0005 | Cherry")
End Sub

Private Sub ComboBox2_DropDownClosed(sender As Object, e As EventArgs) Handles ComboBox2.DropDownClosed
    Dim selecteditem As String = ComboBox2.Items(ComboBox2.SelectedIndex)
    ComboBox2.Text = Strings.Left(selecteditem,4)
    TextBox2.Text = Strings.Left(selecteditem,4)
End Sub

当我从组合框中 select 一个项目时，组合框一直显示整个字符串，而文本框只显示前 4 个字符。

如何在关闭组合框后覆盖组合框文本？

* 编辑 * 我尝试了解决方案的组合，但运行遇到了问题，因为数据已绑定到数据源，因此无法更改项目。这是新代码：

Private Sub ComboBox2_DropDown(sender As Object, e As EventArgs) Handles ComboBox2.DropDown
    SQL.ExecQuery($"select ID, Name, RTRIM(ID + ' | ' + Name) as SingleColumn from GCCTEST.dbo.tblFruit")
    ComboBox2.DataSource = SQL.DBDT
    ComboBox2.DisplayMember = "SingleColumn"
End Sub
Private Sub ComboBox2_DropDownClosed(sender As Object, e As EventArgs) Handles ComboBox2.DropDownClosed
    ComboBox2.DisplayMember = "ID"
    ComboBox2.SelectedIndex = 0
End Sub

现在我只需要将 0 作为我选择的索引...

Answer 1

您可以解决此图形问题，将 Label 放入 Form 并将其移动到 ComboBox 上。

Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load

    Me.Label1.AutoSize = False
    Me.Label1.BackColor = Me.ComboBox1.BackColor
    Me.Label1.Location = New Point(Me.ComboBox1.Location.X + 1, Me.ComboBox1.Location.Y + 1)
    Me.Label1.Size = New Size(Me.ComboBox1.Width - 18, Me.ComboBox1.Height - 2)

    Me.ComboBox1.Items.Add("0001 | Apple")
    Me.ComboBox1.Items.Add("0002 | Pear")
    Me.ComboBox1.Items.Add("0003 | Banana")
    Me.ComboBox1.Items.Add("0004 | Pineapple")
    Me.ComboBox1.Items.Add("0005 | Cherry")

End Sub

Private Sub ComboBox1_SelectedIndexChanged(sender As Object, e As System.EventArgs) Handles ComboBox1.SelectedIndexChanged

    Me.Label1.Text = Trim(Me.ComboBox1.SelectedItem.Split("|")(0))

End Sub

请注意：

您可以在 Form 加载事件期间一次性填充 ComboBox
您可以使用 SelectedIndexChanged 代替 DropDown 和 DropDownClosed 事件
如果这不是图形问题，请查看 DisplayMember and ValueMember 属性

Answer 2

我使用了一些属性和 .net String.SubString 方法而不是旧的 vb6 Strings.Left。

Private Sub ComboBox1_DropDownClosed(sender As Object, e As EventArgs) Handles ComboBox1.DropDownClosed
        Dim SelectedString As String = ComboBox1.SelectedItem.ToString
        Dim ChangedString As String = SelectedString.Substring(0, 4)
        Dim index As Integer = ComboBox1.SelectedIndex
        ComboBox1.Items(index) = ChangedString
End Sub

您可以一个一个地填充您的组合框以避免如下绑定问题...

Private Sub ComboBox1_DropDown(sender As Object, e As EventArgs) Handles ComboBox1.DropDown
        Using cn As New SqlConnection("Your connection string")
            Using cmd As New SqlCommand("Select ID, Name From tblFruit;", cn)
                cn.Open()
                Using dr As SqlDataReader = cmd.ExecuteReader
                    ComboBox1.BeginUpdate()
                    While dr.Read
                        ComboBox1.Items.Add(dr(0).ToString & " | " & dr(1).ToString)
                    End While
                    ComboBox1.EndUpdate()
                End Using
            End Using
    End Using

Answer 3

以下应该有效。如果没有必要，不要在每个下拉菜单中填充组合框，而是在加载 Form.

时调用 FillComboBox 方法

Private Sub FillComboBox()
    SQL.ExecQuery($"select ID, Name, RTRIM(ID + ' | ' + Name) as SingleColumn from GCCTEST.dbo.tblFruit")
    ComboBox2.DataSource = SQL.DBDT
    ComboBox2.DisplayMember = "ID" 
    ComboBox2.ValueMember = "ID"
End Sub

Private Sub ComboBox2_DropDown(sender As Object, e As EventArgs) Handles ComboBox2.DropDown
    Me.ComboBox2.DisplayMember = "SingleColumn"
End Sub

Private Sub ComboBox2_SelectionChangeCommitted(sender As Object, e As EventArgs) Handles ComboBox2.SelectionChangeCommitted
    Dim selV As Object = Me.ComboBox2.SelectedValue

    Me.TextBox2.Text = CStr(selV)
    Me.ComboBox2.DisplayMember = "ID"

    'Set the current value again, otherwise the combobox will always display the first item
    Me.ComboBox2.SelectedValue = selV
End Sub

vb.net 如何在 dropdownclosed 事件后覆盖组合框中的文本

vb.net How to overwrite the text in a combobox after the dropdownclosed event

vb.net

combobox

overwrite