FParsec：如何保存解析器成功的文本

Question

为了在后面的步骤中创建更好的错误消息，我想保存解析器成功的位置以及文本。获得位置似乎很容易（因为有 getPosition 解析器），但我不知道如何访问文本。

假设我有这种类型来保存位置

type SourceLocation = {
    from: Position
    to: Position
    text: string
}

我想创建一个函数，它将 SourceLocation 添加到另一个解析器的结果：

let trackLocation (parser: Parser<'A, 'B>): Parser<SourceLocation * 'A, 'B> =
    let mkLocation ((start: Position, data: 'A), stop: Position: 'Positon) =
        let location = { from = start; to = stop }  // how do I get the text?
        in (location, data)
    getPosition .>>. parser .>>. getPositon |>> mkLocation

因为解析器只是采用 CharStream 的函数，我想我可以使用流和来自我的位置的 Index 来获取文本，但我没有看到获取这个的方法文字.

那么获取解析器成功的文本的正确方法是什么？

Answer 1

我想你可能想要的是 CharStream.ReadFrom method:

Returns a string with the chars between the index of the stateWhereStringBegins (inclusive) and the current Index of the stream (exclusive).

你要做的是：

let trackLocation (parser: Parser<'A, 'B>): Parser<SourceLocation * 'A, 'B> =
    fun (stream : CharStream<'B>) ->
        let oldState = stream.State
        let parseResult = parser stream
        if parseResult.Status = Ok then
            let newState = stream.State
            let matchedText = stream.ReadFrom (oldState, true)
            // Or (oldState, false) if you DON'T want to normalize newlines
            let location = { from = oldState.GetPosition stream
                             ``to`` = newState.GetPosition stream
                             text = matchedText }
            let result = (location, parseResult.Result)
            Reply(result)
        else
            Reply(parseResult.Status, parseResult.Error)

使用示例（也恰好是我写的验证有效的测试代码）：

let pThing = trackLocation pfloat
let test p str =
    match run p str with
    | Success((loc, result), _, _)   -> printfn "Success: %A at location: %A" result loc; result
    | Failure(errorMsg, _, _) -> printfn "Failure: %s" errorMsg; 0.0
test pThing "3.5"
// Prints: Success: 3.5 at location: {from = (Ln: 1, Col: 1);
//                                    to = (Ln: 1, Col: 4);
//                                    text = "3.5";}

编辑： Stephan Tolksdorf（FParsec 的作者）在评论中指出存在 withSkippedString 组合子。那个可能会更简单，因为您不必自己编写使用 CharStream 的函数。（skipped 组合子将 return 解析器匹配的字符串，但不 return 解析器的结果，而 withSkippedString 传递解析器的结果和字符串跳过到您提供的函数中）。通过使用 withSkippedString 组合器，您可以使用原始的 trackLocation 函数，只需进行最小的更改。 trackLocation 的更新版本如下所示：

let trackLocation (parser: Parser<'A, 'B>): Parser<SourceLocation * 'A, 'B> =
    let mkLocation ((start: Position, (text: string, data: 'A)), stop: Position) =
        let location = { from = start; ``to`` = stop; text = text }
        in (location, data)
    getPosition .>>. (parser |> withSkippedString (fun a b -> a,b)) .>>. getPosition |>> mkLocation

（我对此处元组的排列不是 100% 满意，因为它会导致元组内的元组内的元组。不同的组合器顺序可能会产生更好的签名。但由于它是一个内部函数不打算用于 public 消费，函数签名中讨厌的元组嵌套可能没什么大不了的，所以我保留原样。如果你想要更好的函数签名，你可以重新安排它）。

我原来答案中的相同测试代码在这个更新版本的函数上运行良好，并打印相同的结果：开始位置（第 1 行，第 1 列），结束位置（第 1 行，第 4 列），以及已解析的文本 "3.5".

FParsec：如何保存解析器成功的文本

FParsec: How do I save the text on which a parser succeeds

f#

parsing

fparsec