在Delphi中，TBitmap.Monochrome和.PixelFormat如何影响.ScanLine的格式？

Question

我想将具有 Mono8 格式（单色 8 位）位图的给定缓冲区分配给位图。然后我将生成的位图分配给 TImage 组件以显示它。图片是结果显示的屏幕截图。

下面的代码可以工作，但看起来有点浪费：

procedure CopyToBitmapMono824(_Buffer: PByte; _Bmp: TBitmap);
var
  y: Integer;
  x: Integer;
  ScanLine: PdzRgbTripleArray;
begin
  for y := 0 to _Bmp.Height - 1 do begin
    ScanLine := _Bmp.ScanLine[y];
    for x := 0 to _Bmp.Width - 1 do begin
      // monochrome: all 3 colors set to the same value
      ScanLine[x].Red := _Buffer^;
      ScanLine[x].Green := _Buffer^;
      ScanLine[x].Blue := _Buffer^;
      Inc(_Buffer);
    end;
  end;
end;

// [...]
fBmp.PixelFormat := pf24Bit;
FBmp.Monochrome := False;
CopyToBitmap(Buffer, fBmp);

我宁愿使用我尝试过的 pf8Bit 格式的位图：

procedure CopyToBitmapMono8(_Buffer: PByte; _Bmp: TBitmap);
var
  y: Integer;
  x: Integer;
  ScanLine: PByteArray;
begin
  for y := 0 to _Bmp.Height - 1 do begin
    ScanLine := _Bmp.ScanLine[y];
    for x := 0 to _Bmp.Width - 1 do begin
      ScanLine[x] := _Buffer^;
      Inc(_Buffer);
    end;
  end;
end;

// [...]
FBmp.PixelFormat := pf8bit;
FBmp.Monochrome := False; // I also tried Monochrome := true
CopyToBitmapMono8(Buffer, FBmp)

如果MonoChrome为真，图片只有预期宽度的1/4左右，其余为白色。

如果MonoChrome为false，图片有预期的宽度，但左边1/4为单色，其余为假色。

我显然漏掉了什么，但是什么？

编辑：位图只有预期大小的 1/4 的效果显然是在显示之前将其转换为 JPEG 以进行保存的副作用（我没有在上面显示的代码，mea culpa） .所以问题很简单，我没有为位图设置单色调色板。

Answer 1

Monochrome 对 pf1bit 位图有意义。

否则Monochrome := True将位图格式更改为DDB (pfDevice)。您的屏幕是 32 位的，因此调用 Scanline 导致 DibNeeded 调用并转换为 32 位，并且使用函数 CopyToBitmapMono8（用于 8 位）仅填充屏幕的 1/4 .

为了正确使用 8 位位图，您必须将标准的怪异调色板（在最后一张图片的右侧部分使用）更改为灰色。

procedure CopyToBitmapMono8(_Buffer: PByte; _Bmp: TBitmap);
var
  y: Integer;
  x: Integer;
  ScanLine: PByteArray;
begin
  for y := 0 to _Bmp.Height - 1 do begin
    ScanLine := _Bmp.ScanLine[y];
    for x := 0 to _Bmp.Width - 1 do begin
      ScanLine[x] := _Buffer^;
      Inc(_Buffer);
    end;
  end;
end;

var
   FBmp: TBitmap;
   Buffer: PbyteArray;
   i: integer;
begin
  GetMem(Buffer, 512 * 100);
  for i := 0 to 512 * 100 - 1 do
     Buffer[i] := (i and 511) div 2; // gray gradient

  FBmp := Tbitmap.Create;
  FBmp.Width := 512;
  FBmp.Height := 100;
  FBmp.PixelFormat := pf8bit;
  CopyToBitmapMono8(PByte(Buffer), FBmp);
  Canvas.Draw(0, 0, FBmp);

  //now right approach
  FBmp.Palette := MakeGrayPalette; // try to comment
  CopyToBitmapMono8(PByte(Buffer), FBmp);
  Canvas.Draw(0, 110, FBmp);

end;

function TForm1.MakeGrayPalette: HPalette;
var
  i: integer;
  lp:  TMaxLogPalette;
begin
  lp.palVersion    := 0;
  lp.palNumEntries := 256;
  for i := 0 TO 255 do begin
     lp.palPalEntry[i].peRed   := i;
     lp.palPalEntry[i].peGreen := i;
     lp.palPalEntry[i].peBlue  := i;
     lp.palPalEntry[i].peFlags := PC_RESERVED;
   end;
   Result := CreatePalette(pLogPalette(@lp)^);
end;

And example at efg2 page

在Delphi中，TBitmap.Monochrome和.PixelFormat如何影响.ScanLine的格式？

In Delphi, how does TBitmap.Monochrome and .PixelFormat influcence the format of .ScanLine?

delphi

tbitmap