将 IRAM 的优先级赋予 C 中的特定源文件

Question

我正在寻找一种方法，将 IRAM 的优先级分配给特定的源文件，默认情况下让其他源文件优先。

在 Keil uVision 中，我可以通过进入文件选项来做到这一点：

我将我的项目迁移到 Atollic TrueSTUDIO（使用 CubeMx 生成），但没有类似的选项。我在链接描述文件 STM32F765NG_FLASH.id.

中找到了有关如何设置 RAM 启动位置及其大小的信息

/* Specify the memory areas */
MEMORY
{
RAM (xrw)      : ORIGIN = 0x20000000, LENGTH = 512K
FLASH (rx)      : ORIGIN = 0x08000000, LENGTH = 1024K
}

我想可能有一种方法可以修改此文件以指定哪个 .c 文件需要 IRAM 上的优先级，但我不知道在哪里以及如何做。

我还发现我可以在变量声明中使用 __ attribute__。当我使用它时，它会编译，但会破坏代码的某些功能（它可能会覆盖其他数据）。

uint8_t __attribute__((section(".ARM.__at_0x20000000"))) RxSerialDMABuffer[RX_DMA_BUFFER_SIZE] = {0};
uint8_t __attribute__((section(".ARM.__at_0x20001000"))) TxDMABuffer[TX_DMA_BUFFER_SIZE] = {0};

所以我的问题是，在没有 Keil uVision 选项的情况下，如何设置一个特定的源文件优先使用 IRAM 优先于所有其他文件？

编辑：这是完整的链接描述文件

/*
*****************************************************************************
**

**  File        : stm32_flash.ld
**
**  Abstract    : Linker script for STM32F765NG Device with
**                1024KByte FLASH, 512KByte RAM
**
**                Set heap size, stack size and stack location according
**                to application requirements.
**
**                Set memory bank area and size if external memory is used.
**
**  Target      : STMicroelectronics STM32
**
**  Environment : Atollic TrueSTUDIO(R)
**
**  Distribution: The file is distributed as is, without any warranty
**                of any kind.
**
**  (c)Copyright Atollic AB.
**  You may use this file as-is or modify it according to the needs of your
**  project. This file may only be built (assembled or compiled and linked)
**  using the Atollic TrueSTUDIO(R) product. The use of this file together
**  with other tools than Atollic TrueSTUDIO(R) is not permitted.
**
*****************************************************************************
*/

/* Entry Point */
ENTRY(Reset_Handler)

/* Highest address of the user mode stack */
_estack = 0x20080000;    /* end of RAM */
/* Generate a link error if heap and stack don't fit into RAM */
_Min_Heap_Size = 0x00002200;      /* required amount of heap  */
_Min_Stack_Size = 0x00001200; /* required amount of stack */

/* Specify the memory areas */
MEMORY
{
RAM (xrw)      : ORIGIN = 0x20000000, LENGTH = 512K
FLASH (rx)      : ORIGIN = 0x08000000, LENGTH = 1024K
}

/* Define output sections */
SECTIONS
{
  /* The startup code goes first into FLASH */
  .isr_vector :
  {
    . = ALIGN(4);
    KEEP(*(.isr_vector)) /* Startup code */
    . = ALIGN(4);
  } >FLASH

  /* The program code and other data goes into FLASH */
  .text :
  {
    . = ALIGN(4);
    *(.text)           /* .text sections (code) */
    *(.text*)          /* .text* sections (code) */
    *(.glue_7)         /* glue arm to thumb code */
    *(.glue_7t)        /* glue thumb to arm code */
    *(.eh_frame)

    KEEP (*(.init))
    KEEP (*(.fini))

    . = ALIGN(4);
    _etext = .;        /* define a global symbols at end of code */
  } >FLASH

  /* Constant data goes into FLASH */
  .rodata :
  {
    . = ALIGN(4);
    *(.rodata)         /* .rodata sections (constants, strings, etc.) */
    *(.rodata*)        /* .rodata* sections (constants, strings, etc.) */
    . = ALIGN(4);
  } >FLASH

  .ARM.extab   : { *(.ARM.extab* .gnu.linkonce.armextab.*) } >FLASH
  .ARM : {
    __exidx_start = .;
    *(.ARM.exidx*)
    __exidx_end = .;
  } >FLASH

  .preinit_array     :
  {
    PROVIDE_HIDDEN (__preinit_array_start = .);
    KEEP (*(.preinit_array*))
    PROVIDE_HIDDEN (__preinit_array_end = .);
  } >FLASH
  .init_array :
  {
    PROVIDE_HIDDEN (__init_array_start = .);
    KEEP (*(SORT(.init_array.*)))
    KEEP (*(.init_array*))
    PROVIDE_HIDDEN (__init_array_end = .);
  } >FLASH
  .fini_array :
  {
    PROVIDE_HIDDEN (__fini_array_start = .);
    KEEP (*(SORT(.fini_array.*)))
    KEEP (*(.fini_array*))
    PROVIDE_HIDDEN (__fini_array_end = .);
  } >FLASH

  /* used by the startup to initialize data */
  _sidata = LOADADDR(.data);

  /* Initialized data sections goes into RAM, load LMA copy after code */
  .data : 
  {
    . = ALIGN(4);
    _sdata = .;        /* create a global symbol at data start */
    *(.data)           /* .data sections */
    *(.data*)          /* .data* sections */

    . = ALIGN(4);
    _edata = .;        /* define a global symbol at data end */
  } >RAM AT> FLASH


  /* Uninitialized data section */
  . = ALIGN(4);
  .bss :
  {
    /* This is used by the startup in order to initialize the .bss secion */
    _sbss = .;         /* define a global symbol at bss start */
    __bss_start__ = _sbss;
    *(.bss)
    *(.bss*)
    *(COMMON)

    . = ALIGN(4);
    _ebss = .;         /* define a global symbol at bss end */
    __bss_end__ = _ebss;
  } >RAM

  /* User_heap_stack section, used to check that there is enough RAM left */
  ._user_heap_stack :
  {
    . = ALIGN(4);
    PROVIDE ( end = . );
    PROVIDE ( _end = . );
    . = . + _Min_Heap_Size;
    . = . + _Min_Stack_Size;
    . = ALIGN(4);
  } >RAM



  /* Remove information from the standard libraries */
  /DISCARD/ :
  {
    libc.a ( * )
    libm.a ( * )
    libgcc.a ( * )
  }

  .ARM.attributes 0 : { *(.ARM.attributes) }
}

Answer 1

TrueSTUDIO 使用 GNU 工具链，因此 GNU linker documentation applies. Specifically in the case the part dealing with section placement。

类似于（注意以下是一个片段；您的真实链接描述文件将包含更多内容或组织方式可能不同）：

MEMORY
{
    ...

    IRAM1 (xrw)       : ORIGIN = 0x20020000, LENGTH = 384K
    IRAM2 (xrw)       : ORIGIN = 0x20000000, LENGTH = 128K
}

SECTIONS
{
   DATA_IRAM1 :
   {
      * (.data)

   } > IRAM1 AT > FLASH

   BSS_IRAM1 :
   {
      * (.bss)

   } > IRAM1

   DATA_IRAM2 :
   {
      Buffers.o (.data) /* locate Buffers initialised data here */ 
      * (.data)

   } > IRAM2 AT > FLASH

   BSS_IRAM2 :
   {
      Buffers.o (.bss) /* locate Buffers zero-int data here */ 
      * (.bss)  

   } > IRAM2
}

通配符 * (.bss) 允许任何目标模块的 BSS 位于指定的部分，而 Buffers.o (.bss) 使 Buffers.o BSS 的位置明确。 .data.

同样

如果您看过 Keil 生成的链接描述文件，您会发现它直接受 GUI 对话框中设置的影响，并且会看到类似的指令 - 然而 ARM 链接器使用的语法与 GNU 略有不同我认为，但它可能仍然有帮助，看看它如何为您的特定部分组织内存和位置 - 您发布的片段似乎有些通用并且没有将 IRAM 分成例如 TCM 等专业部分。

Answer 2

为了让 RAM 优先于我的缓冲区，我先将它们加载到 RAM 中。

通过使用文件名，链接器报告了多个定义的错误。所以我像在我的问题中所做的那样向我的缓冲区添加了一个部分属性，但是通过给出部分名称而不是地址。

uint8_t RxSerialDMABuffer[RX_DMA_BUFFER_SIZE] __attribute__ ((section ("BUFFERS"))) = {0};
uint8_t TxDMABuffer[TX_DMA_BUFFER_SIZE] __attribute__ ((section ("BUFFERS"))) = {0};

在此之后，我在 RAM 中将新部分添加到其他未初始化数据之前。

  /* Uninitialized buffers section */
  .BUFFERS :
  {
    * (.BUFFERS)
  } >RAM

  /* Uninitialized data section */
  . = ALIGN(4);
  .bss :
  {
    /* This is used by the startup in order to initialize the .bss secion */
    _sbss = .;         /* define a global symbol at bss start */
    __bss_start__ = _sbss;
    *(.bss)
    *(.bss*)
    *(COMMON)

    . = ALIGN(4);
    _ebss = .;         /* define a global symbol at bss end */
    __bss_end__ = _ebss;
  } >RAM

然后我进入链接器地址映射文件，我看到所有缓冲区的地址都对应于我的 IRAM2 地址范围，所有其他未初始化的数据的下一个地址在 IRAM2，然后是 IRAM1。

将 IRAM 的优先级赋予 C 中的特定源文件

Give the priority of the IRAM to a specific source file in C

c

memory

embedded

ram

truestudio