为 coq (ssreflect) 中的记录推导标准结构

Question

鉴于以下假设：

Variable A : finType.
Variable B : finType.
Variable C : finType.

记录定义为：

Record example := Example {
       example_A : A;
       example_B : B;
       example_C : C;
}.

直觉上，示例似乎也必须是 finType。

查看其他代码库，我看到人们使用

形式的构造为只有一个非证明术语的记录导出 finType

Definition <record>_subType := Eval hnf in [subtype for <record-accessor>].
Definition <record>_finMixin := Eval hnf in [finMixin of <record> by <:].

但在这种情况下，记录有多个字段。

有没有自动导出记录的fintype的方法，如果没有，如何导出记录的fintype？

Answer 1

数学组件中的许多接口实现都可以通过表明您的类型是实现该接口的其他一些类型的缩回来派生。在您的示例中，我们只需要将记录转换为元组即可。

From mathcomp Require Import
  ssreflect ssrfun ssrbool ssrnat eqtype seq choice fintype.

Variables A B C : finType.

Record example := Example {
  example_A : A;
  example_B : B;
  example_C : C
}.

Definition prod_of_example e :=
  let: Example a b c := e in (a, b, c).

Definition example_of_prod p :=
  let: (a, b, c) := p in Example a b c.

Lemma prod_of_exampleK : cancel prod_of_example example_of_prod.
Proof. by case. Qed.

Definition example_eqMixin :=
  CanEqMixin prod_of_exampleK.
Canonical example_eqType :=
  Eval hnf in EqType example example_eqMixin.
Definition example_choiceMixin :=
  CanChoiceMixin prod_of_exampleK.
Canonical example_choiceType :=
  Eval hnf in ChoiceType example example_choiceMixin.
Definition example_countMixin :=
  CanCountMixin prod_of_exampleK.
Canonical example_countType :=
  Eval hnf in CountType example example_countMixin.
Definition example_finMixin :=
  CanFinMixin prod_of_exampleK.
Canonical example_finType :=
  Eval hnf in FinType example example_finMixin.

在此代码段的末尾，example 被声明为 finType。（请注意 eqType、choiceType 等所有其他声明也是必需的，因为 finType 是它们的子类。）

为 coq (ssreflect) 中的记录推导标准结构

Deriving a cannonical structure for a record in coq (ssreflect)

coq

ssreflect