带有命名参数的信号

Question

我正在尝试使用 PySide2 复制以下示例。

但由于 PySide2 不支持向 QML 发出带有命名参数的信号，我不知道如何使用 PySide2 执行此操作？

这是我的代码

main.py

from PySide2.QtGui import QGuiApplication
from PySide2.QtQml import QQmlApplicationEngine
from PySide2.QtCore import QObject, Signal, Slot, Property


class Calculator(QObject):
    def __init__(self):
        QObject.__init__(self)

    sumResult = Signal(int)
    subResult = Signal(int)

    @Slot(int, int)
    def sum(self, arg1, arg2):
        self.sumResult.emit(arg1 + arg2)

    @Slot(int, int)
    def sub(self, arg1, arg2):
        self.subResult.emit(arg1 - arg2)


if __name__ == "__main__":
    import sys

    app = QGuiApplication(sys.argv)
    engine = QQmlApplicationEngine()
    calculator = Calculator()
    engine.rootContext().setContextProperty("calculator", calculator)
    engine.load("/code/QML/calc.qml")

    engine.quit.connect(app.quit)
    sys.exit(app.exec_())

Answer 1

你不能像这样复制它，如果你想实现这个项目你可以让插槽return的值：

main.py

from PySide2 import QtCore, QtGui, QtQml


class Calculator(QtCore.QObject):
    # Slot for summing two numbers
    @QtCore.Slot(int, int, result=int)
    def sum(self, arg1, arg2):
        return arg1 + arg2

    # Slot for subtraction of two numbers
    @QtCore.Slot(int, int, result=int)
    def sub(self, arg1, arg2):
        return arg1 - arg2


if __name__ == "__main__":
    import os
    import sys

    # Create an instance of the application
    app = QtGui.QGuiApplication(sys.argv)
    # Create QML engine
    engine = QtQml.QQmlApplicationEngine()
    # Create a calculator object
    calculator = Calculator()
    # And register it in the context of QML
    engine.rootContext().setContextProperty("calculator", calculator)
    # Load the qml file into the engine
    file = os.path.join(os.path.dirname(os.path.realpath(__file__)), "main.qml")
    engine.load(file)

    engine.quit.connect(app.quit)
    sys.exit(app.exec_())

main.qml

import QtQuick 2.5
import QtQuick.Controls 1.4
import QtQuick.Layouts 1.2
 
ApplicationWindow {
    visible: true
    width: 640
    height: 240
    title: qsTr("PyQt5 love QML")
    color: "whitesmoke"
 
    GridLayout {
        anchors.top: parent.top
        anchors.left: parent.left
        anchors.right: parent.right
        anchors.margins: 9
 
        columns: 4
        rows: 4
        rowSpacing: 10
        columnSpacing: 10
 
        Text {
            text: qsTr("First number")
        }
 
        // Input field of the first number
        TextField {
            id: firstNumber
        }
 
        Text {
            text: qsTr("Second number")
        }
 
        // Input field of the second number
        TextField {
            id: secondNumber
        }
 
        Button {
            height: 40
            Layout.fillWidth: true
            text: qsTr("Sum numbers")
 
            Layout.columnSpan: 2
 
            onClicked: {
                // Invoke the calculator slot to sum the numbers
                sumResult.text = calculator.sum(firstNumber.text, secondNumber.text)
            }
        }
 
        Text {
            text: qsTr("Result")
        }
 
        // Here we see the result of sum
        Text {
            id: sumResult
        }
 
        Button {
            height: 40
            Layout.fillWidth: true
            text: qsTr("Subtraction numbers")
 
            Layout.columnSpan: 2
 
            onClicked: {
                // Invoke the calculator slot to subtract the numbers
                subResult.text = calculator.sub(firstNumber.text, secondNumber.text)
            }
        }
 
        Text {
            text: qsTr("Result")
        }
 
        // Here we see the result of subtraction
        Text {
            id: subResult
        }
    }
}

注意： 对于 PyQt5，将 Slot 更改为 pyqtSlot。

带有命名参数的信号

Signal with named parameter

python

qml

pyside2