cfi_adjust_cfa_offset 和 cfi_rel_offset 是什么？

Question

我目前正在尝试了解 glibc 的 syscall 函数的内部代码。下面是代码（取自from here）.

/* In the EABI syscall interface, we don't need a special syscall to
   implement syscall().  It won't work reliably with 64-bit arguments
   (but that is true on many modern platforms).  */
ENTRY (syscall)
        mov        ip, sp
        push        {r4, r5, r6, r7}
        cfi_adjust_cfa_offset (16)
        cfi_rel_offset (r4, 0)
        cfi_rel_offset (r5, 4)
        cfi_rel_offset (r6, 8)
        cfi_rel_offset (r7, 12)
        mov        r7, r0
        mov        r0, r1
        mov        r1, r2
        mov        r2, r3
        ldmfd        ip, {r3, r4, r5, r6}
        swi        0x0
        pop        {r4, r5, r6, r7}
        cfi_adjust_cfa_offset (-16)
        cfi_restore (r4)
        cfi_restore (r5)
        cfi_restore (r6)
        cfi_restore (r7)
        cmn        r0, #4096
        it        cc
        RETINSTR(cc, lr)
        b        PLTJMP(syscall_error)
PSEUDO_END (syscall)

对传递系统调用号和参数的代码有了一些了解，这些是syscall函数的核心功能。但是我不明白cfi_adjust_cfa_offset指令、cfi_rel_offset指令和cfi_restore指令是做什么的。我知道这些说明与 syscall 函数的功能关系不大。但是，我仍然想知道这些说明的作用。

谢谢。

Answer 1

这些不是指令，而是 assembler directives (normally they should start with a . but here they are macros，可能是为了处理汇编程序中的差异）。它们告诉汇编程序对特殊元数据进行编码，这有助于调试器和异常处理程序正确展开堆栈。通常它们是由编译器发出的，所以你看不到它们，但它们在低级代码或像这里这样的手写汇编中特别重要。

让我们看一下代码。首先，一些背景。

CFA 代表 "Canonical Frame Address"，默认情况下等于调用站点 (see here) 的 sp 的值。在 ARM 调用中，不要将 return 地址压入堆栈，因此函数入口处的 sp 是相同的。

mov ip, sp

这会将 sp 值（即 CFA，因此指向不适合 r0-r3 寄存器的任何其他参数）复制到 ip（又名 r12 ）登记。

push {r4,r5,r6, r7}

这会保存即将修改但假定不会被调用修改的寄存器（非易失性寄存器）。推送改变sp值4*4=16个字节，不再等于CFA

cfi_adjust_cfa_offset(16)

这会发出一个操作码，告诉调试器 CFA 与假定的 CFA (sp) 的偏移量为 16。

cfi_rel_offset(r4, 0)

这告诉调试器 r4 的原始值可以在新调整的 CFA 的偏移量 0 处找到。以下指令描述了其他三个保存的寄存器。

    mov        r7, r0
    mov        r0, r1
    mov        r1, r2
    mov        r2, r3
    ldmfd        ip, {r3, r4, r5, r6}
    swi        0x0

这会以 EABI 调用约定所期望的方式设置系统调用参数（r7 中的系统调用编号，r0-r6 中的第一个参数），然后调用系统调用指令

    pop        {r4, r5, r6, r7}
    cfi_adjust_cfa_offset (-16)
    cfi_restore (r4)
    cfi_restore (r5)
    cfi_restore (r6)
    cfi_restore (r7)

这里恢复之前保存的寄存器，将CFA调回-16（因为sp被pop指令改变了，说明寄存器已经恢复到原来的值).

cfi_adjust_cfa_offset 和 cfi_rel_offset 是什么？

what is cfi_adjust_cfa_offset and cfi_rel_offset?

assembly

arm

instruction-set

instructions

eabi