在不使用循环的情况下在 Fortran 中用零填充数组

Question

我有两个数组，我想比较它们的大小并将尾随零添加到较短的数组中。

例如-对于数组-

y1=(/ 1,2,3 /)
y2=(/ 1,2,3,4,5 /)

最后的结果应该是——

y1=(/ 1,2,3,0,0 /)
y2=(/ 1,2,3,4,5 /)

我是 Fortran 的新手，据我所知，可以这样做:-

integer, allocatable :: y1(:),y2(:)
integer :: l1,l2,i
.
.
.
! some code to generate y1 and y2 here
.
.
.
l1=size(y1)
l2=size(y2)

if (l1>l2) then
    do i=l2+1,l1
        y2(i)=0
    enddo
else if (l2>l1) then
    do i=l1+1,l2
        y1(i)=0
    enddo
endif

我想知道是否有更好的方法，最好是不涉及循环的方法，因为我正在处理的实际问题可能有巨大的向量

Answer 1

这是一种方法：

y1 = RESHAPE(y1,SHAPE(y2),pad=[0])

没有明确的循环。正如@VladimirF 评论的那样，必须重新分配较短的数组，这种方法将其留给编译器和运行时间来处理。

如果您担心这种方法的性能，或者担心它的性能 wrt 使用显式循环的版本，并且担心性能如何随数组大小变化，然后运行一些测试。如果发现显式重新分配和一两个循环比这种 'clever' 方法更快，我不会感到惊讶。

Answer 2

如果您只关心秩为 1 的数组，那么使用 SHAPE 和 RESHAPE 就太过分了。只需使用 Fortran 的数组构造函数功能即可。您还可以使用现代 Fortran 的分配分配功能，因此您不需要重新分配较短的数组。

program foo
  implicit none
  integer, allocatable :: y1(:),y2(:)
  integer :: l1,l2,i
  y1 = [1, 2, 3]
  y2 = [1, 2, 3, 4, 5]
  l1 = size(y1)
  l2 = size(y2)
  if (l1 > l2) y2 = [y2, [(0,i=1,l1-l2)]]
  if (l2 > l1) y1 = [y1, [(0,i=1,l2-l1)]]
  print '(10(I0,1X))', y1
  print '(10(I0,1X))', y2
end program foo

在不使用循环的情况下在 Fortran 中用零填充数组

Padding an array with zeroes in fortran without using loops

fortran

gfortran

fortran90

fortran95