Arduino Wire 库返回错误代码 7（库中未定义）

Question

我正在使用 ESP32 尝试从 IMU MPU-6050 读取数据。我使用的是 Arduino 网站上提供的代码，略有不同；我正在检查 endTransmission 上的错误代码并打印它（我开始这样做是因为我从读取 MPU 寄存器的调用中得到了所有零值）。在第一次调用初始化 MPU 时，我收到一个成功错误代码。但是在那之后我收到错误代码 7 的永远调用。奇怪的是，当我跟踪 Wire 库时，我发现没有定义错误代码 7。有问题的函数只有 4 个可能的 return 值，而 7 个不是其中之一。

这是完整的代码。

    #include<Wire.h>
    const int MPU_addr=0x68;  // I2C address of the MPU-6050
    int16_t AcX,AcY,AcZ,Tmp,GyX,GyY,GyZ;
    int initialError;
    void setup(){
      Wire.begin();
      Wire.beginTransmission(MPU_addr);
      Wire.write(0x6B);  // PWR_MGMT_1 register
      Wire.write(0);     // set to zero (wakes up the MPU-6050)
      initialError = Wire.endTransmission(true);
      Serial.begin(9600);

    }
    void loop(){
      int error ;
      Wire.beginTransmission(MPU_addr);
      Wire.write(0x3B);  // starting with register 0x3B (ACCEL_XOUT_H)
      error = Wire.endTransmission(false);
      if(error)
      {
        Serial.print("Errors: ");
        Serial.print(initialError);
        Serial.print(" ");
        Serial.println(error);
      }
      else {
        Wire.requestFrom(MPU_addr,14,true);  // request a total of 14 registers
        AcX=Wire.read()<<8|Wire.read();  // 0x3B (ACCEL_XOUT_H) & 0x3C (ACCEL_XOUT_L)    
        AcY=Wire.read()<<8|Wire.read();  // 0x3D (ACCEL_YOUT_H) & 0x3E (ACCEL_YOUT_L)
        AcZ=Wire.read()<<8|Wire.read();  // 0x3F (ACCEL_ZOUT_H) & 0x40 (ACCEL_ZOUT_L)
        Tmp=Wire.read()<<8|Wire.read();  // 0x41 (TEMP_OUT_H) & 0x42 (TEMP_OUT_L)
        GyX=Wire.read()<<8|Wire.read();  // 0x43 (GYRO_XOUT_H) & 0x44 (GYRO_XOUT_L)
        GyY=Wire.read()<<8|Wire.read();  // 0x45 (GYRO_YOUT_H) & 0x46 (GYRO_YOUT_L)
        GyZ=Wire.read()<<8|Wire.read();  // 0x47 (GYRO_ZOUT_H) & 0x48 (GYRO_ZOUT_L)
        Serial.print("AcX = "); Serial.print(AcX);
        Serial.print(" | AcY = "); Serial.print(AcY);
        Serial.print(" | AcZ = "); Serial.print(AcZ);
        Serial.print(" | Tmp = "); Serial.print(Tmp/340.00+36.53);  //equation for temperature in degrees C from datasheet
        Serial.print(" | GyX = "); Serial.print(GyX);
        Serial.print(" | GyY = "); Serial.print(GyY);
        Serial.print(" | GyZ = "); Serial.println(GyZ);
        delay(333);
      }
    }

initialError 为零（成功），另一个错误为 7（？）。任何人都知道这里发生了什么以及如何纠正？

Answer 1

我发现了问题。好吧，这并不是一个真正的问题，而是一个不同的实现。

EPS32 使用的是 Wire 库的不同实现。它具有其他 return 值，而与 Arduino 软件一起打包的值则没有。

                typedef enum {
                    I2C_ERROR_OK=0,
                    I2C_ERROR_DEV,      // 1
                    I2C_ERROR_ACK,     // 2
                    I2C_ERROR_TIMEOUT, // 3
                    I2C_ERROR_BUS,     // 4
                    I2C_ERROR_BUSY,    // 5
                    I2C_ERROR_MEMORY,  // 6
                    I2C_ERROR_CONTINUE,// 7
                    I2C_ERROR_NO_BEGIN // 8
                } i2c_err_t;

错误代码 7 表示请求已排队。他们还没有被发送。任何时候在这个实现中用 false 调用 Wire::EndTransmission 而不是实际发送请求，请求只是排队。当以 true 作为参数（或没有 qrgument）调用 endTransmission 时，所有请求都会立即发送。

这种实现差异的另一个含义是将非零值视为错误的代码不一定能正常工作，因为并非所有非零值都是真正的错误代码。

对于我的情况，我可以使用 Wire::endTransmission(true)。对于其他运行解决此问题的人，您的解决方案可能需要更多考虑和可能的逻辑更改。

Arduino Wire 库返回错误代码 7（库中未定义）

Arduino Wire Library returning Error Code 7 (which is not defined in the library)

arduino

esp32

mpu6050