Oracle Apex - 在 varray-table-field 中保存数字列表

Question

我有一个 table 和 varray 的数字字段 type aptitude_list as varray(60) of number 并且想要 save/update 一个逗号分隔的列表，其中包含一个顶点文本字段。

我的 SQL 声明如下：

INSERT INTO tbl_aptitude (ID, APTITUDE)
VALUES ('12345678', aptitude_list(1,2,3,4));

并且在 SQL 开发人员中工作正常。

现在我想用我的文本字段 aptitude_list(:P7_APTITUDE) 和 P7_APTITUDE='1,2,3,4' 替换数字。这无法保存，因为 '1,2,3,4' 不是有效数字。

如何告诉系统我要存储四个不同的数字而不是一个？

感谢您的帮助！

Answer 1

在 Oracle 中有 many, many ways 分割定界字符串。

一种方法是使用函数：

Oracle 设置:

CREATE type aptitude_list as varray(60) of number
/

CREATE OR REPLACE FUNCTION split_String(
  i_str    IN  VARCHAR2,
  i_delim  IN  VARCHAR2 DEFAULT ','
) RETURN aptitude_list DETERMINISTIC
AS
  p_result       aptitude_list := aptitude_list();
  p_start        NUMBER(5) := 1;
  p_end          NUMBER(5);
  p_count        NUMBER(3) := 0;
  c_len CONSTANT NUMBER(5) := LENGTH( i_str );
  c_ld  CONSTANT NUMBER(5) := LENGTH( i_delim );
BEGIN
  IF c_len > 0 THEN
    p_end := INSTR( i_str, i_delim, p_start );
    WHILE p_end > 0 LOOP
      p_result.EXTEND;
      p_result( p_result.COUNT ) := SUBSTR( i_str, p_start, p_end - p_start );
      p_start := p_end + c_ld;
      p_end := INSTR( i_str, i_delim, p_start );
    END LOOP;
    IF p_start <= c_len + 1 THEN
      p_result.EXTEND;
      p_result( p_result.COUNT ) := SUBSTR( i_str, p_start, c_len - p_start + 1 );
    END IF;
  END IF;
  RETURN p_result;
END;
/

CREATE TABLE tbl_aptitude (
  ID       VARCHAR2(20),
  APTITUDE aptitude_list
);

那么你可以使用：

INSERT INTO tbl_aptitude (ID, APTITUDE)
VALUES ('12345678', split_String(:P7_APTITUDE));

查询:

SELECT *
FROM   tbl_aptitude;

输出:

| ID       | APTITUDE               |
|----------|------------------------|
| 12345678 | APTITUDE_LIST(1,2,3,4) |

Oracle Apex - 在 varray-table-field 中保存数字列表

Oracle Apex - Save list of numbers in a varray-table-field

oracle

varray

nested-table

oracle-apex