分配前匹配的声明

Question

我正在为我正在构建的编程语言制作解析器，运行遇到一个问题：ANTLR 似乎有意不匹配变量声明。
这是语法：

// Define a grammar called simc
grammar simc;

//Parser Rules
program : statement+ ;
statement : declaration | assignment | ( expression SEMICOLON ) ;
expression          : LEFTPAREN expression RIGHTPAREN                 #parenthesisExp
                    //Math
                    | <assoc=right>  expression '^' expression        #powerExp
                    | expression (ASTERISK|SLASH) expression          #mulDivExp
                    | expression (PLUS|MINUS) expression              #addSubExp
                    //Bool Operations
                    | expression EQUALITY expression                  #equalCompExp
                    | expression NONEQUALITY expression               #notequalCompExp
                    | expression GREATERTHAN expression               #greaterCompExp
                    | expression LESSTHAN expression                  #lessCompExp
                    | expression GREATERTHANOREQUALTO expression      #greaterorequalCompExp
                    | expression LESSTHANOREQUALTO expression         #lessorequalCompExp                   
                    //Any value that isn't an expression itself
                    | value                                           #valueExp
                    ;
value : constvalue | functioncall | variable ;
functioncall : IDENTIFIER LEFTPAREN expression? ( COMMA expression )? RIGHTPAREN ;
declaration : typelabel variable EQUALS expression SEMICOLON ;
assignment : variable EQUALS expression SEMICOLON ;
constvalue : intvalue | floatvalue | stringvalue | boolvalue ;
typelabel : INTLABEL | FLOATLABEL | STRINGLABEL | BOOLLABEL ;
variable : IDENTIFIER ;
intvalue : INTVALUE ;
floatvalue : FLOATVALUE ;
stringvalue : STRINGVALUE ;
boolvalue : BOOLVALUE ;

//Lexer Rules
IDENTIFIER : [a-zA-Z][a-zA-Z0-9]* ;
LEFTPAREN : '(' ;
RIGHTPAREN : ')' ;
INTLABEL : I N T ;
FLOATLABEL : F L O A T ;
STRINGLABEL : S T R I N G ;
BOOLLABEL : B O O L ;
INTVALUE : [0-9]+ ;
FLOATVALUE : [0-9]+ ( PERIOD [0-9]+ F? | F ) ;
STRINGVALUE : QUOTE ( '\"' | . )*? QUOTE ;
BOOLVALUE : ( T R U E ) | ( F A L S E ) ;
SEMICOLON : ';' ;
ASTERISK : '*' ;
SLASH : '/' ;
PLUS : '+' ;
MINUS : '-' ;
EQUALS : '=' ;
EQUALITY : '==' ;
NONEQUALITY : '!=' ;
GREATERTHAN : '>' ;
LESSTHAN : '<' ;
GREATERTHANOREQUALTO : '>=' ;
LESSTHANOREQUALTO : '<=' ;
COMMA : ',' ;
PERIOD : '.' ;
QUOTE : '"' ;
fragment A : [aA] ; // match either an 'a' or 'A'
fragment B : [bB] ;
fragment C : [cC] ;
fragment D : [dD] ;
fragment E : [eE] ;
fragment F : [fF] ;
fragment G : [gG] ;
fragment H : [hH] ;
fragment I : [iI] ;
fragment J : [jJ] ;
fragment K : [kK] ;
fragment L : [lL] ;
fragment M : [mM] ;
fragment N : [nN] ;
fragment O : [oO] ;
fragment P : [pP] ;
fragment Q : [qQ] ;
fragment R : [rR] ;
fragment S : [sS] ;
fragment T : [tT] ;
fragment U : [uU] ;
fragment V : [vV] ;
fragment W : [wW] ;
fragment X : [xX] ;
fragment Y : [yY] ;
fragment Z : [zZ] ;
WS : [ \r\t\n]+ -> skip ;
COMMENT : ( ( '/' '/' .*? ( '\r'|'\t'|'\n' ) ) | '/*' .*? '*/' ) -> skip ;

如果我没记错的话，语法应该匹配代码 int a = 5; 作为变量的声明。相反，我得到一个空语句（我不明白该特定事件是如何发生的），一个标记为不正确的包含 int 文本的语句（在我的测试中，它仅适用于有效的类型名称）和正确的分配。据我所知，声明应该在赋值之前找到，对吗？为什么会这样匹配，我该如何解决？

Answer 1

如果您查看为您的输入生成的标记，您会发现它将 int 视为 IDENTIFIER，而不是 INTLABEL。发生这种情况是因为您在语法中的 INTLABEL 之前定义了 IDENTIFIER 并且当多个词法分析器规则可以匹配相同数量的输入时，它将使用语法中排在第一位的规则。因此，您应该始终在关键字之后 定义标识符规则。

分配前匹配的声明

Declaration Matched Before Assignment

c#

antlr

antlr4