在联合查询中使用维基数据标签服务

Question

我想知道是否可以在联合查询中使用维基数据标签服务。例如，以下查询

# Query from a local SPARQL enpoint

select ?item ?itemLabel
where {
    SERVICE <https://query.wikidata.org/sparql> {
        ?item wdt:P31 wd:Q146.
        SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
    }

}

returns 空 ?itemLabels。我怎样才能在我的结果集中获得 ?itemLabels？

Answer 1

包括一些名义上可选的东西...这是完整的 query I just ran through URIBurner.com, and its results。

PREFIX       wdt:  <http://www.wikidata.org/prop/direct/>
PREFIX        wd:  <http://www.wikidata.org/entity/>
PREFIX        bd:  <http://www.bigdata.com/rdf#>
PREFIX  wikibase:  <http://wikiba.se/ontology#>

SELECT *
WHERE
  {
    SERVICE <https://query.wikidata.org/sparql>
      {
        SELECT ?item ?itemLabel 
        WHERE 
          {
            ?item wdt:P31 wd:Q146 .
            SERVICE wikibase:label
              { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
          }
      }
  }

Answer 2

你也可以使用 manual mode，在你的情况下它只是多了一行：

PREFIX       wdt:  <http://www.wikidata.org/prop/direct/>
PREFIX        wd:  <http://www.wikidata.org/entity/>
PREFIX        bd:  <http://www.bigdata.com/rdf#>
PREFIX  wikibase:  <http://wikiba.se/ontology#>
PREFIX      rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT * {
  SERVICE <https://query.wikidata.org/sparql> {
    ?item wdt:P31 wd:Q146
    SERVICE wikibase:label { bd:serviceParam wikibase:language "it". ?item rdfs:label ?label }
  }
}

Try on FactForge

在联合查询中使用维基数据标签服务

Using Wikidata label service in federated queries

sparql

wikidata

federated-queries