将相关矩阵转置为SAS中的一个长向量

Question

我正在尝试将相关矩阵转换为一个长列向量，以便我具有以下结构

data want;
input _name1_$ _name2_$ _corr_;
datalines;
var1 var2 0.54
;
run;

我有以下代码，它输出 name1 和 corr；但是，我正在努力获得 name2!

DATA TEMP_1
    (DROP=I J);
    ARRAY VAR[*] VAR1-VAR10;
    DO I = 1 TO 10;
        DO J = 1 TO 10;
            VAR(J) = RANUNI(0);
        END;
        OUTPUT;
    END;
RUN;

PROC CORR
    DATA=TEMP_1
    OUT=TEMP_CORR
        (WHERE=(_NAME_ NE " ")
         DROP=_TYPE_)
    ;
RUN;

PROC SORT DATA=TEMP_CORR; BY _NAME_; RUN;

PROC TRANSPOSE
    DATA=TEMP_CORR
    OUT=TEMP_CORR_T
    ;
    BY _NAME_;
RUN;

感谢帮助

Answer 1

你很接近。您运行遇到了 name 变量的奇怪问题，因为它也成为 PROC TRANSPOSE 之外的变量。如果你重命名它，你会得到你想要的。我还明确列出了变量并添加了一些重命名数据集选项以获得您可能想要的内容。

PROC TRANSPOSE
DATA=TEMP_CORR (rename=_name_ = Name1)
OUT=TEMP_CORR_T (rename = (_name_ = Name2 col1=corr))
;
by name1;
var var1-var10;
RUN;

编辑：如果您不想重复，您可以将 WHERE 添加到 OUT 数据集。

PROC TRANSPOSE
DATA=TEMP_CORR (rename=_name_ = Name1)
OUT=TEMP_CORR_T (rename = (_name_ = Name2 col1=corr) where = name1 > name2)
;
by name1;
var var1-var10;
RUN;

Answer 2

只是一个带有 VNAME() 函数的数组。要仅输出上三角，将 DO 循环的下限设置为 _N_。

data want ;
  length _name1_ _name2_  _corr_ 8 ;
  keep _name1_ _name2_ _corr_;
  set corr;
  where _type_ = 'CORR';
  array x _numeric_;
  _name1_=_name_;
  do i=_n_ to dim(x);
    _name2_ = vname(x(i));
    _corr_ = x(i);
    output;
  end;
run;

将相关矩阵转置为SAS中的一个长向量

Transpose a correlation matrix into one long vector in SAS

arrays

transpose

sas

pearson-correlation

sas-studio