Netlogo

Question

我正在为仓库排队系统建模。主要代理是包裹和分拣机。分拣机从特定命名的缓冲队列（例如 q-1、q-2、q-3...q-n）中拉取包裹进行分拣。我不想将缓冲区队列建模为代理，而是想将它们表示为全局列表变量。

问题是如何将分拣机设置为能够动态识别和操作不同的特定全局变量（q-1、q-2 ...q-n）？

Answer 1

您可能有一个附加的变量以创建该变量的字符串表示，然后在执行该字符串后将全局变量存储在局部变量中：

我没有测试它，但这应该有效：

let parcel-number 2
let parcel run-result (word "q-" parcel-number)

或者

run (word "let parcel q-" 2)

查看此处了解更多信息：https://ccl.northwestern.edu/netlogo/docs/dictionary.html#run

Answer 2

I do not want to model the buffer queue as agents

为什么？

我相信你有自己的理由，但它们可能值得重新考虑。

每当我看到像 q-1、q-2...q-n 这样的变量名时，我都会害怕地退缩。您正在尝试建模某种东西，从概念上讲，它是事物的集合。单一变量意味着指代单一事物。编程语言具有表示事物集合的数据结构，而这些通常是完成这项工作的正确工具。

在 NetLogo 中，这些数据结构（主要）是代理集和列表。

我的直觉告诉我，正确的方法是将队列建模为拥有列表变量的海龟，但如果您真的不想这样做，您始终可以使用列表的全局列表来存储队列.这是一个例子：

globals [ queues ]

to setup
  clear-all
  set queues n-values 3 [ (list) ] ; create three empty queues
  add-to-queue 0 "A"
  add-to-queue 0 "B"
  add-to-queue 1 "X"
  print queues
  print poll-from-queue 0
  print queues
end

to add-to-queue [ queue-index new-item ]
  let old-queue item queue-index queues
  let new-queue lput new-item old-queue
  set queues replace-item queue-index queues new-queue
end

to-report poll-from-queue [ queue-index ]
  let old-queue item queue-index queues
  let polled-item first item queue-index queues
  let new-queue but-first old-queue
  set queues replace-item queue-index queues new-queue
  report polled-item
end

在您的模型中，队列当然会存储包裹而不是字符串。

Netlogo - 动态选择不同的全局变量

Netlogo - dynamically choose the different global variables

global-variables