从 QML 中的数组中的 bool 更改颜色

Question

我希望从数组 (calendarListModel) 中的布尔值更改日历单元格的颜色。

这是数组的示例：

[
{"date":1544443200000,"name":"Edward","status":1},
{"date":1544529600000,"name":"Katie","status":0},
{"date":1544616000000,"name":"Claire","status":1}
]

我想做的是根据 calendarListModel ("status": 0 or 1).[=21 中的布尔值更改日历标记的颜色=]

我的标记代码是；

Rectangle {
    id: calendarMarker
    visible: arrayFromFireBase.indexOf(styleData.date.getTime()) > -1
    anchors.fill: parent
    color:  "blue"
}

我已经尝试使用 calendarListModel.status ? "blue" : "red" 等其他变体来更改矩形的颜色，但是我要么将每个单元格设置为蓝色或红色，要么根本就是 none？

问题：根据数组中的 true/false 值更改颜色的最佳方法是什么？

我正在使用 QtQuick.Controls 中的 Calendar 来显示日期，并使用 QtQuick.Controls.Styles 中的 CalendarStyle 来指定自定义样式。我也在用V-Play sdk。

这是我目前正在做的一个最小的、完整的、可验证的例子：

import VPlayApps 1.0
import QtQuick 2.2
import QtQuick.Controls 1.4
import QtQuick.Controls.Styles 1.1

App {
    id: app

    //  this model is read from a firebase db using v-play
    property var calendarListModel: [
        {"date":1544443200000,"name":"Edward","status":1},
        {"date":1544529600000,"name":"Katie","status":0},
        {"date":1547182800000,"name":"Claire","status":1}
    ]

    Calendar {
        id: calendar
        anchors.fill: parent
        selectedDate: new Date()
        weekNumbersVisible: true
        focus: true
        onSelectedDateChanged: {
            const day = selectedDate.getDate();
            const month = selectedDate.getMonth() + 1;
            const year = selectedDate.getFullYear();
        }

       style: CalendarStyle {
           dayOfWeekDelegate: Item {
               width: parent.width
               height: dp(30)
               Rectangle {
                   anchors.fill: parent
                   border.color: "#00000000"
                   Label {
                       id: dayOfWeekDelegateText
                       text: Qt.locale().dayName(styleData.dayOfWeek, Locale.ShortFormat)
                       anchors.centerIn: parent
                       color: "black"
                   }
               }
           }

           //  a delegate for each day cell
           dayDelegate: Item {
               id: container

               readonly property color sameMonthDateTextColor: "#444"
               readonly property color selectedDateColor: "#20d5f0"
               readonly property color selectedDateTextColor: "white"
               readonly property color differentMonthDateTextColor: "#bbb"

               //  the background of each cell
               Rectangle {
                   anchors.fill: parent
                   border.color: "#00000000"
                   color: styleData.selected ? selectedDateColor : "white"
               }

               //  a marker on the upper-left corner on each cell
               Rectangle {
                   id: calendarMarker
                   property bool isConfirmed: false
                   anchors {
                       top: parent.top; left: parent.left
                   }

                   width: 12
                   height: width

                   //  the issue lies here
                   color: {
                        var confCol
                        calendarListModel.indexOf(status? true : false)
                        confCol ? "#4286f4" : "red"
                   }

               }

               // the day number
               Label {
                   id: dayDelegateText
                   text: styleData.date.getDate()
                   anchors.centerIn: parent
                   color:  styleData.selected ? selectedDateTextColor : styleData.visibleMonth ? sameMonthDateTextColor : differentMonthDateTextColor
               }
            }
        }
    }
}

Answer 1

好的，现在您正在使用一个对象数组并试图直接对其进行索引，这并不好。（特别是因为您当前正在为 true/false 值编制索引，这些值不包含 calendarListModel 中的单个元素。）即使您可以使用日期、名称重建对象，和地位，他们仍然是不同的对象。

改用Array.prototype.find()。

color: {
    var modelObject = calendarListModel.find(
       function(obj) {
            //  look for a matching date
           return obj.date === styleData.date.getTime();
       }
    );

    if (modelObject === undefined)  //  not found in list model
       return "lightgrey";

    return modelObject.status ? "blue" : "red";
}

这是在 macOS 上测试前后的对比：

之前：注意所有标记都是红色的。只有 calendarListModel 中指定的日期应该有颜色。

之后：请注意，只有 1 月 11 日的标记有颜色（蓝色）。实际上，这是因为日期包含在 calendarListModel 中：1544616000000。

从 QML 中的数组中的 bool 更改颜色

Change colour from bool within array in QML

javascript

arrays

boolean

qml

v-play