有没有办法将整个笔记本导出到不同的部分

Question

我正在寻找将一个 evernote 笔记本导出到不同部分的可能性，例如：

Notebook = Eingang (2000Notes)

可能导出到

Eingang1.enex (500注)
Eingang2.enex (500Notes)
Eingang3.enex (500Notes)
Eingang3.enex (500Notes)

因为处理（即导入到 Onenote）经常失败，导致 ENEX 文件中的笔记太多或太大。也许有一些脚本或其他任何可行的方法。仅手动导出不是正确的方法，因为我有包含 14k+ 笔记的笔记本。我希望我的意图越来越清楚。预先感谢您的帮助。

Answer 1

如果您使用的是 Mac，Evernote 的 AppleScript 词典会公开一个 export 动词，您可以针对该动词构建工具。这是一个有点不优雅但功能齐全的 AppleScript 来做你正在寻找的东西，只需编辑批处理大小、笔记本名称和你希望 ENEX 文件进入的路径：

tell application "Evernote"
    # Set batch size, notebook to export, and destination path
    set batchSize to 500
    set theNotebookName to "MyNotebook"
    set theExportFolder to "/tmp"

    # Enumerate the notes into batches and export them
    set theNotebook to the first notebook whose name is theNotebookName
    set theNotes to the notes in theNotebook
    set currentBatchIndex to 0
    set currentNoteIndex to 1
    repeat until currentNoteIndex = (count of theNotes)
        # Collect up to batchSize notes
        set thisExportBatch to {}
        repeat until ((count of thisExportBatch) = batchSize or (currentNoteIndex = (count of theNotes)))
            set currentItem to theNotes's item currentNoteIndex
            set thisExportBatch to thisExportBatch & {currentItem}
            set currentNoteIndex to currentNoteIndex + 1
        end repeat
        # Export this batch. Set the destination path to where you want them.
        set exportPath to (theExportFolder & "/" & theNotebookName & currentBatchIndex & ".enex")
        export thisExportBatch to exportPath
        set currentBatchIndex to (currentBatchIndex + 1)
    end repeat
end tell

我不确定 Windows 上的等价物是什么，但我希望有一些等价的方法可以使它自动化。

有没有办法将整个笔记本导出到不同的部分

Is there any way to export entire notebook in different parts

export

evernote