Batch 7zip，将文件压缩到没有任何文件夹的存档中

Question

我是批处理新手，目前正在练习创建自动化脚本。我现在坚持这个。我希望 zip 文件只包含 tm_user.data，但我的代码会将其存档为 Fame\tm_user.data。如果你们中有人能帮助我，我将不胜感激。

变量

set default_folder_name=Main Folder
set tm_folder_name=TM Folder
set local_dir=C:\%default_folder_name%
set tm_dir=%local_dir%\%tm_folder_name%

正文

set /p id="Enter ID: "
set d = "tm_user.data"

if exist "%tm_dir%\%id%\Fame\%d%" (
    "C:\Program Files-Zipz.exe" a -tzip "%tm_dir%\%id%\Fame\%id%_fame.zip" "%tm_dir%\%id%\Fame\%d%"
    echo Process completed...
    timeout 2
    start "launch folder" "%tm_dir%\%id%\Fame"
    exit
) else (
        echo Error: %d% not found, please try again later!!
        timeout 5
        exit
    )
)

Answer 1

批处理文件的一些最佳实践。

不要在 SET 命令中的等号两边放置空格。等号之前的空格成为变量名称的一部分，等号之后的空格被分配给变量。
不要为变量分配引号，但要用引号括起分配以保护特殊字符并避免将尾随空格分配给变量的末尾。

我选择使用 PUSHD 和 POPD 命令。 PUSHD 命令设置工作目录并将之前的目录存储在堆栈中。 POPD 命令returns 回到以前存放的目录。使用此技术，您不必在 7zip 命令中指定路径。

@echo off
set "default_folder_name=Main Folder"
set "tm_folder_name=TM Folder"
set "local_dir=C:\%default_folder_name%"
set "tm_dir=%local_dir%\%tm_folder_name%"

set /p "id=Enter ID: "
set "d=tm_user.data"

if exist "%tm_dir%\%id%\Fame\%d%" (
    pushd "%tm_dir%\%id%\Fame"
    "C:\Program Files-Zipz.exe" a -tzip "%id%_fame.zip" "%d%"
    echo Process completed...
    timeout 2
    start .
    popd
    exit
) else (
    echo Error: %d% not found, please try again later!!
    timeout 5
    exit
)

Batch 7zip，将文件压缩到没有任何文件夹的存档中

Batch 7zip, Zip file into archive without any folders

7zip

batch-file