Google 表查询 select 当某些值

Question

我试图使下面的公式按如下方式工作：当 B 与 E 上的值匹配时获取 A 上的值（对于示例，它将是 1、2、4、5、7、8）。

=QUERY({IMPORTRANGE("1Cg9gx2IhBUYwElNXprNJnihixbMLJcK1DKzIClQDNwc";"DATA!A2:C")};"select Col1 Where Col3 >= date '"&TEXT(TODAY;"yyyy-mm-dd")&"'and Col3 <= date '"&TEXT(TODAY;"yyyy-mm-dd")&"'and Col2="&(E1:E2)&"";0)

示例数据：

A   B   C           E
1   X   27/02/2019  X
2   Y   27/02/2019  Y
3   Z   27/02/2019  
4   X   27/02/2019  
5   Y   27/02/2019  
6   Z   27/02/2019  
7   X   27/02/2019  
8   Y   27/02/2019

我怎样才能做到这一点？

Answer 1

尝试 "where" 子句：

where  Col2='"&E3&"' or Col2 ='"&E2&"'

Answer 2

QUERY 无法处理引用部分内的 array/range
TODAY 需要像 TODAY()

()

今天是 2 月 28 日（至少我 sheet 住的地方）

=QUERY(IMPORTRANGE("1Cg9gx2IhBUYwElNXprNJnihixbMLJcK1DKzIClQDNwc"; "DATA!A2:C");
 "select Col1 
  where Col3 >= date '"&TEXT(TODAY(); "yyyy-MM-dd")&"'
    and Col3 <= date '"&TEXT(TODAY(); "yyyy-MM-dd")&"'
    and (Col2 = '"&E1&"'
     or  Col2 = '"&E2&"')"; 0)

如果您有 array/range 个值，也可以这样尝试：

=QUERY(FILTER(IMPORTRANGE("1Cg9gx2IhBUYwElNXprNJnihixbMLJcK1DKzIClQDNwc"; "DATA!A2:C100"); 
 COUNTIF(E1:E100; "="&
 IMPORTRANGE("1Cg9gx2IhBUYwElNXprNJnihixbMLJcK1DKzIClQDNwc"; "DATA!B2:B100"))); 
 "select Col1 
   where Col3 >= date '"&TEXT(TODAY(); "yyyy-MM-dd")&"' 
     and Col3 <= date '"&TEXT(TODAY(); "yyyy-MM-dd")&"'"; 0)

Google 表查询 select 当某些值

Google sheets query select when certain values

google-sheets

google-query-language