Listview 实例子项

Question

我的目标是根据 OleDb 查询的输出数据填充列表视图。我可以毫无问题地正确填充项目和一个子项目。但是我在定义每个项目的其他 4 个子项目时遇到了麻烦。

如您所知，通常您使用

定义子项

ListView1.Items(0).SubItems(1).Text = "Test Item 2"

但是在使用在运行时填充我的 Control Listview 的 Listview 实例时，我无法弄清楚如何做到这一点。

这是我的代码，它成功地填充了一个项目和一个子项目：

    Dim conn As New System.Data.OleDb.OleDbConnection(connectionString)
    Dim com As System.Data.OleDb.OleDbCommand
    Dim reader As System.Data.OleDb.OleDbDataReader

    Try
        'Open the connection
        conn.Open()
        'Create a new instance of the command and provide the SELECT query, and the opened connection
        com = New System.Data.OleDb.OleDbCommand("SELECT * FROM Schedules", conn)
        reader = com.ExecuteReader(CommandBehavior.CloseConnection)

        'Check to see if the SELECT query returned any rows
        If reader.HasRows Then
            'If so, perform a read for each row
            While reader.Read
                'Declare a new ListViewItem, and provide the information
                'to be shown in the very first column
                Dim item As New ListViewItem(reader.Item("colName").ToString)
                'Decare a new ListViewSubItem, and provide the information
                'to be shown in the second (and so forth) column
                Dim subItem As New ListViewItem.ListViewSubItem
                subItem.Text = reader.Item("colNextRun").ToString

                'Ideally, I'd like to add "colLastRun as another sub item
                'subItem1.Text = reader.Item("colLastRun").ToString

                'Add the ListViewSubItem to the ListViewItem
                item.SubItems.Add(subItem)
                'Add the ListViewItem to the ListView
                lv.Items.Add(item)
                'Repeat until all rows have been read
            End While
        End If
        'Close the reader
        reader.Close()

    Catch ex As Exception
        'If something went sideways, make sure that you close the connection
        'before exiting the method.
        If conn.State = ConnectionState.Open Then
            'MsgBox(ex.Message)
            conn.Close()
        End If
    End Try

Answer 1

好吧，在查看了我在此处发布的自己的问题后，我有了一个想法。 我想通了：

您只需要定义第二个子项.. 呸！

                'Decare a new ListViewSubItem, and provide the information
                'to be shown in the second (and so forth) column
                Dim subItem As New ListViewItem.ListViewSubItem
                Dim subItem1 As New ListViewItem.ListViewSubItem()
                Dim subItem2 As New ListViewItem.ListViewSubItem
                subItem.Text = reader.Item("colNextRun").ToString
                subItem1.Text = reader.Item("colLastRun").ToString
                subItem2.Text = reader.Item("colFileLocation").ToString
                'Add the ListViewSubItem to the ListViewItem
                item.SubItems.Add(subItem)
                item.SubItems.Add(subItem1)
                item.SubItems.Add(subItem2)

Answer 2

恭喜您找到了解决方法。您在连接方面做得非常好，但不仅需要关闭连接，还需要处理连接。查看 Using blocks ，它可以为您解决这两个问题。即使出现错误，它们也会关闭并处置您的数据库对象。

您不需要为每个子项创建一个子项对象。子项集合的 .Add 方法可以采用一个字符串，该字符串将为该子项提供文本。它会在内部创建子项目并将其添加到集合中。

请注意在 ListView 上使用 .BeginUpdate 和 .EndUpdate。如果您要添加很多项目，这将大大加快速度。它可以防止控件在每次添加时重新绘制。添加完所有项目后会重新绘制一次。

Private Sub FillListView()
    Using conn As New OleDbConnection("Your connection string")
        Using cmd As New OleDbCommand("SELECT * FROM Schedules", conn)
            conn.Open()
            Using reader = cmd.ExecuteReader
                ListView1.BeginUpdate()
                While reader.Read
                    Dim item As New ListViewItem(reader.Item("colName").ToString)
                    item.SubItems.Add(reader.Item("NextcolName").ToString)
                    item.SubItems.Add(reader.Item("NextcolName").ToString)
                    item.SubItems.Add(reader.Item("NextcolName").ToString)
                    ListView1.Items.Add(item)
                End While
                ListView1.EndUpdate()
            End Using
        End Using
    End Using
End Sub

Listview 实例子项

Listview Instance Subitems

vb.net

listview

oledbdatareader