将文件夹名称附加到文件名并使用 DOS 批处理移动文件

Question

有这样的文件夹结构：

rootfolder\subfolder1\file1.txt
rootfolder\subfolder1\fileA.txt
rootfolder\subfolderX\file2.txt
rootfolder\subfolderX\fileC.txt

需要将文件夹名附加到文件名并包括当前日期时间。然后将重命名的文件移动到根文件夹，如下所示：

rootfolder\subfolder1_file1_<datetime>.txt
rootfolder\subfolder1_fileA_<datetime>.txt
rootfolder\subfolderX_file2_<datetime>.txt
rootfolder\subfolderX_fileC_<datetime>.txt

有人知道可以执行此操作的脚本吗？非常感谢！

Answer 1

@ECHO OFF
SETLOCAL
SET "sourcedir=U:\sourcedir"
SET "datetime=%date:/=-%%time::=.%"
PUSHD "%sourcedir%"
FOR /f "delims=" %%a IN (
  'dir /b /ad "%sourcedir%\*"'
  ) DO (
 FOR /f "delims=" %%d IN ('dir /b/a-d ".\%%a\*.txt" 2^>nul') DO (
  ECHO(move "%sourcedir%\%%a\%%d" "%sourcedir%\%%a_%%~nd_%datetime%%%~xd"
 )
)
popd

GOTO :EOF

您需要更改 sourcedir 的设置以适合您的情况。

我选择简单地过滤 .txt 个文件 - 调整文件掩码以适应。

我不知道您的日期格式或您期望的日期格式。您还没有说要插入 current date/time 还是 file's date/time。 current假设。

所需的 MOVE 命令仅 ECHOed 用于测试目的。 确认命令正确后，将ECHO(MOVE 更改为MOVE 以实际移动文件。附加 >nul 以禁止报告消息（例如 1 file moved）

将文件夹名称附加到文件名并使用 DOS 批处理移动文件

Append folder name to file name and move file using DOS batch

windows

file

batch-file