如何使用 Winsock api 检查互联网连接？

Question

我在下面构建了这段代码（基于 this 示例）以使用 Winsock api 检查是否存在与互联网的连接并尝试向特定网站发出 GET 请求（google.com 在我的例子中）。

但是WSAGetLastErrorreturns错误代码：10051.

如何解决这个问题？

program Project1;

uses
  Windows, SysUtils, WinSock;

function GetIPFromHostName(const HostName: string): string;
var
  WSAData: TWSAData;
  R: PHostEnt;
  A: TInAddr;
begin
  Result := '0.0.0.0';
  WSAStartup(1, WSAData);
  R := GetHostByName(PAnsiChar(AnsiString(HostName)));
  if Assigned(R) then
  begin
    A := PInAddr(R^.h_Addr_List^)^;
    Result := WinSock.inet_ntoa(A);
  end;
end;

function IsConnectedToInternet: Boolean;
var
  WSAData1: TWSAData;
  SockAddr1: TSockAddr;
  Socket1: TSocket;
begin
  Result := False;

  if WSAStartup(MAKEWORD(2, 2), WSAData1) <> 0 then
  begin
    Writeln('WinSock error');
    Exit;
  end;

  Socket1 := Socket(AF_INET, SOCK_STREAM, 0);
  if Socket1 = INVALID_SOCKET then
  begin
    Writeln('socket error');
    Exit;
  end;

  SockAddr1.sin_family := AF_INET;
  SockAddr1.sin_addr.S_addr := inet_addr(PAnsiChar(GetIPFromHostName('google.com')));
  SockAddr1.sin_port := htons(80);

  if Connect(Socket1, SockAddr1, SizeOf(SockAddr1)) <> 0 then
  begin
    Writeln('connection error #', WSAGetLastError);
    Exit;
  end;

  Result := True;

  if CloseSocket(Socket1) <> 0 then
    Writeln('error closing socket');
end;

begin
  IsConnectedToInternet;
  readln;

end.

Answer 1

编译器警告您错误，在您填写 sockaddr_in 的 in_addr 行：

W1044 Suspicious typecast of string to PAnsiChar

inet_addr 需要一个 ANSI 字符串。您正在将 unicode 字符串类型转换为 PAnsiChar，从而传递格式错误的字符串，导致 connect 无法找到目标。

替换

SockAddr1.sin_addr.S_addr := inet_addr(PAnsiChar(GetIPFromHostName('google.com')));

和

SockAddr1.sin_addr.S_addr :=
    inet_addr(PAnsiChar(AnsiString(GetIPFromHostName('google.com'))));

您可以使用为此目的设计的 API 之一，例如 InternetCheckConnection, or InternetGetConnectedState, or INetworkListManager 接口（Vista 和更高版本）。

例如

const
  FLAG_ICC_FORCE_CONNECTION = 1;
begin
  if not InternetCheckConnection('http://google.com', FLAG_ICC_FORCE_CONNECTION, 0) then
    RaiseLastOSError;

如何使用 Winsock api 检查互联网连接？

How check internet connection using Winsock api?

sockets

delphi

winsock

delphi-10-seattle