如何获得多槽中的项目总和

Question

我有一个如下所示的模板。如何获得多槽等级中的项目总和？

(deftemplate student
  (multislot name)
  (multislot grades)
)

Answer 1

您可以使用expand$功能。查看 Basic Programming Guide 和 Multifield Expansion Function 章节以了解更多信息。

(deftemplate student 
  (multislot name) 
  (multislot grades))  

(defrule grades-sum 
  (student (grades $?grades)) 
  => 
  (printout t "Student grades sum is " (+ (expand$ ?grades)))) 

(assert (student (grades (create$ 1 2 3 4 5)))) 
(student (name) (grades 1 2 3 4 5))

(run)       
Student grades sum is 15

Answer 2

这是一种方法。在 reg6 规则中，除了成绩之外，+ 函数还被赋予两个参数 0，以确保 + 函数允许至少有 2 个参数；否则，如果学生的成绩为零或一个，你会得到一个错误。

         CLIPS (6.31 2/3/18)
CLIPS> 
(deftemplate student
  (multislot name)
  (multislot grades))
CLIPS> 
(deftemplate sum
   (multislot name)
   (slot grade))
CLIPS>    
(defrule reg6
   (student (name $?name)
            (grades $?grades))
   =>
   (assert (sum (name ?name)
                (grade (+ 0 0 (expand$ ?grades))))))
CLIPS> 
(assert (student (name David Green) (grades))
        (student (name Sue Brown) (grades 90))
        (student (name Frank Black) (grades 85 75)))
<Fact-3>
CLIPS> (run)
CLIPS> (facts)
f-0     (initial-fact)
f-1     (student (name David Green) (grades))
f-2     (student (name Sue Brown) (grades 90))
f-3     (student (name Frank Black) (grades 85 75))
f-4     (sum (name Frank Black) (grade 160))
f-5     (sum (name Sue Brown) (grade 90))
f-6     (sum (name David Green) (grade 0))
For a total of 7 facts.
CLIPS>

如何获得多槽中的项目总和

How can I get the sum of items in a multislot

clips