ESP32 + DEEP SLEEP + I2C - 中断问题

Question

我在 ISR（中断模式）中执行 deepsleep 和 i2c 通信时遇到问题。

我正在使用这个库在 Arduino 中编码 IDE :

https://github.com/espressif/arduino-esp32

https://techtutorialsx.com/2017/09/30/esp32-arduino-external-interrupts/

当我在 void loop() 函数中运行它对 i2c（例如打开 LED）工作正常，但是当我将它移植到中断时它不起作用。

和deepsleep一样，不能在中断模式下执行。我绕过它的方法是在中断模式下设置一个标志以表明我想深度睡眠，然后在 void loop() 函数中执行它。

有没有人对如何使这项工作有任何解决方案？（代码仅适用于 i2c 和 esp32）

#include <Wire.h>

#if defined(ARDUINO_ARCH_SAMD)
// for Zero, output on USB Serial  console, remove line below if using programming port to program the Zero!
   #define Serial SerialUSB
#endif

// Interrupt Setup - TIMER
hw_timer_t * timer = NULL; //configure the timer, need pointer to a variable type of hw_timer_t
portMUX_TYPE timerMux = portMUX_INITIALIZER_UNLOCKED; // used to sync main loop and ISR
RTC_DATA_ATTR bool should_sleep = false;

// Setting ADC Properties - BATTERY
int voltage_amplifier = 0; 
int battery_percentage = 0; 

// Set i2c Address - I/O EXPANDER
const int address = 0x20;
uint16_t led_status = word(B11111111,B11111111);

// INTERRUPT MODE - INSERT INBETWEEN portENTER and portEXIT
void IRAM_ATTR onTimer() {
  portENTER_CRITICAL_ISR(&timerMux);
  // led_battery();        led doesn't update if used here
  portEXIT_CRITICAL_ISR(&timerMux);
}

void led_battery(){
    voltage_amplifier = analogRead(34);
    Serial.println(voltage_amplifier);
    int bit_max = 4096;
    int battery_percentage = voltage_amplifier*100/bit_max;

    // If battery is below 20%
    if (battery_percentage <= 20){
      led_status &= word(B00111111,B11111111); // clearing the bits that we want to change whilst preserving the other unchanged bits
      led_status |= ~word(B11000000,B00000000); // setting up the bits that we want to change
      pf575_write(led_status);
    }

    else if (battery_percentage <= 40){
      led_status &= word(B00011111,B11111111); // clearing the bits that we want to change whilst preserving the other unchanged bits
      led_status |= ~word(B11100000,B00000000); // setting up the bits that we want to change
      pf575_write(led_status);
    }

    else if (battery_percentage <= 60){
      led_status &= word(B00001111,B11111111); // clearing the bits that we want to change whilst preserving the other unchanged bits
      led_status |= ~word(B11110000,B00000000); // setting up the bits that we want to change
      pf575_write(led_status);
    }

    else if (battery_percentage <= 80){
      led_status &= word(B00000111,B11111111); // clearing the bits that we want to change whilst preserving the other unchanged bits
      led_status |= ~word(B11111000,B00000000); // setting up the bits that we want to change
      pf575_write(led_status);
    }

    else if (battery_percentage <= 100){
      led_status &= word(B00000011,B11111111); // clearing the bits that we want to change whilst preserving the other unchanged bits
      led_status |= ~word(B11111100,B00000000); // setting up the bits that we want to change
      pf575_write(led_status);
    }
}

void ioexpander_setup(){
  while (!Serial);             // Leonardo: wait for serial monitor
  Serial.println("\n Blinker Ready");
  Wire.begin();
}

void pf575_write(uint16_t data) {
  Wire.beginTransmission(address);
  Wire.write(lowByte(data));
  Wire.write(highByte(data));
  Wire.endTransmission();
}

void timer_setup(){
  // Base Clock Frequency = 80MHz ; Timer Frequency = 1MHz | Clock Cycle = 1us [in this case]
  timer = timerBegin(0,80,true); // return a pointer to a structure of type hw_timer_t

  // Timer binded to a handling function
  timerAttachInterrupt(timer, &onTimer, true); // Parameter : (timer_initialization, address_interrupt,flag_to_activate - true(edge)/false(level))

  // Specify the counter value in which the timer interrupt will be generated (set every 10 ms)
  timerAlarmWrite(timer, 10000, true); // Parameter : (timer_initialization, when_to_interrupt (us), flag_to_reload)

  // Enable the timer
  timerAlarmEnable(timer);
}

void setup() {
  Serial.begin(115200);

  // IO Expander
  ioexpander_setup();

  // Timer
  timer_setup();

}

void loop() {  
  led_battery();    //led update if used here
}

Answer 1

当您从中断处理程序调用 led_battery() 时，您在那里做的工作太多了。

中断可以中断任何没有中断锁定的东西。

假设您的代码正在使用 Serial 输出一些内容并且发生了定时器中断。现在您的代码是运行 Serial 内部某处的代码，您再次调用 Serial...而软件和硬件可能处于不一致状态。

从中断处理程序执行的每个子例程和硬件访问都是这种情况。防止这种情况的唯一方法是在您的代码可能访问硬件或可能修改数据结构时禁用中断。

不幸的是，禁用中断很容易出错 - 如果您忘记这样做，就会出现莫名其妙的崩溃。如果你忘记重新启用它们，你就有大麻烦了——你的网络、定时器和串口都将停止工作。它还会为您的代码增加很多开销。而且它会降低您的整体系统性能 - 它会延迟或导致您错过网络和计时器事件。您可以从串行端口删除字符。您可以确定 Arduino Core 中的 none 代码正在为您执行此操作。

所以，长话短说，锁定中断以便您可以在中断处理程序中做很多事情是不切实际的。

您还想尽量减少花在中断处理程序上的时间，因为这会抢占网络堆栈、定时器、串行和其他硬件处理，并可能阻塞其他

你在你原来的 post 中指出了我们处理这个问题的方法：在中断处理程序中设置一个标志（确保它是 volatile）并在任务中处理它。除非您真的非常了解自己在做什么以及系统中所有软件的工作方式，否则这是处理此问题的唯一实用方法。如果您尝试完成大量工作并从中断处理程序调用您正在调用的东西，您的程序将出现故障并崩溃。

ESP32 + DEEP SLEEP + I2C - 中断问题

ESP32 + DEEP SLEEP + I2C - Interrupt Problem

microcontroller

arduino

esp32