如何在 GNU Smalltalk 中添加具有 2 个不同名称的相同方法？

Question

如何让 class 公开具有 2 个不同名称的相同方法？

例如asDescripton 函数做同样的事情/重新导出 asString 函数而无需简单地复制粘贴代码。

Object subclass: Element [
  | width height |

  Element class >> new [
    ^super new init.
  ]

  init [
    width := 0.
    height := 0.
  ]

  asString [
    ^ 'Element with width ', width, ' and height ', height.
  ]

  asDescription [ "???" ]
]

Answer 1

正如lurker在评论中所写，在asDescription中发送asString消息。

asDescription
    ^ self asString

通常这样做是为了从 class 公开额外的 interfaces/protocols，以实现兼容性或作为内置适配器。如果您创建的新内容不必适合其他任何地方，请考虑为每个操作坚持使用一个名称。

编辑：如果你真的在重新导出语义之后并且不希望在上面的委托中涉及额外的消息发送，可能有一种方法将 asString 的 CompiledMethod 放在 [= 的方法字典中19=] 第二次使用其他名称。但我不确定这是否可行，我也不知道 GNU Smalltalk 中的协议如何操作方法字典。查看 Behavior class 的文档。另外，我不认为这是对 Smalltalk 进行编程，而是在修补系统。

Answer 2

在 Smalltalk 中，您通常会实现 #printOn: 并从其继承版本中获取 #asString，该版本位于

行

Object >> asString
  | stream |
  stream := '' writeStream.
  self printOn: stream.
  ^stream contents

该方法的实际实现可能在您的环境中略有不同，思路是一样的。

鉴于此，实施 #printOn: 而不是 #asString 通常是个好主意。在您的情况下，您会将其实现为

Element >> printOn: aStream
  aStream
    nextPutAll: 'Element with width ';
    nextPutAll: width asString;
    nextPutAll: ' and height ';
    nextPutAll: height asString

然后，正如 JayK 和 luker 指出的那样，

Element >> asDescription
  ^self asString

换句话说，您（通常）不想实施 #asString，而是 #printOn:。这种方法更好，因为它利用了继承并确保 #printOn: 和 #asString 之间的一致性，这通常是预期的。此外，它将让您有机会开始熟悉 Streams，它在 Smalltalk 中起着核心作用。

请注意，在我的实现中我使用了 width asString 和 heigh asString。您的代码尝试将 String 与 Number:

连接（两次）

'Element with width ', width, ' and height ', height.

这将不起作用，因为您只能将 String 的实例与 #,.

连接起来

然而，在大多数方言中，您可以通过使用 #print: 而不是 #nextPutAll: 来避免发送 #asString，例如：

Element >> printOn: aStream
  aStream
    nextPutAll: 'Element with width ';
    print: width;
    nextPutAll: ' and height ';
    print: height

比较简洁，因此更受欢迎。

最后一件事。我建议用这个更改上面的第一行：

    nextPutAll: self class name;
    nextPutAll: ' with width ';

而不是对 class 名称进行硬编码。如果将来您使用 subclass Element，这将被证明是有用的，因为您将不需要调整 #printOn: 及其任何衍生物（例如，#asDescription）。

最终想法：我会将选择器 #asDescription 重命名为 #description。介词 as 旨在将一个对象转换为另一个不同的 class （这就是 #asString 可以的原因）。但是这里好像不是这样。

附录：为什么？

#asString 是根据 #printOn: 实施的，而不是相反： 通用性 是有原因的。虽然工作量（代码复杂性）相同，但 #printOn: 显然是赢家，因为它可以与 any 字符 Stream 一起使用。特别是，它无需任何修改即可使用

文件（FileStream的实例）
套接字（SocketStream 的实例）
Transcript

换句话说，通过实施 #printOn: 可以免费（继承）获得 #asString 并且——同时——能够将对象的表示形式转储到文件和套接字上. Transcript 特别有趣，因为它支持 Stream 写入协议，因此可用于在向外部设备发送任何字节之前进行测试。

记住！

在 Smalltalk 中，目标是同时拥有行为简单且一般的对象，不只是简单！

如何在 GNU Smalltalk 中添加具有 2 个不同名称的相同方法？

How to add same method with 2 different names in GNU Smalltalk?

smalltalk

gnu-smalltalk

附录：为什么？

记住！