从数字数组中获取数字

Question

要将数字拆分为给定基数中的数字，Julia 具有 digits() 函数：

julia> digits(36, base = 4)
3-element Array{Int64,1}:
 0
 1
 2

什么是反向操作？如果您有一个数字数组和基数，是否有内置方法将其转换为数字？我可以将数组打印成一个字符串并使用 parse()，但这听起来效率低下，而且对于大于 10 的基数也不起作用。

Answer 1

答案好像直接写在了digits的文档里面：


help?> digits
search: digits digits! ndigits isdigit isxdigit disable_sigint

  digits([T<:Integer], n::Integer; base::T = 10, pad::Integer = 1)

  Return an array with element type T (default Int) of the digits of n in the given base,
  optionally padded with zeros to a specified size. More significant digits are at higher
  indices, such that n == sum([digits[k]*base^(k-1) for k=1:length(digits)]).

所以对于你的情况，这会起作用：

julia> d = digits(36, base = 4);

julia> sum([d[k]*4^(k-1) for k=1:length(d)])
36

上面的代码可以用点运算符缩短：

julia> sum(d.*4 .^(0:(length(d)-1)))
36

Answer 2

前面的回答都对，但还有效率问题：

sum([x[k]*base^(k-1) for k=1:length(x)])

在求和之前将数字收集到一个数组中，这会导致不必要的分配。跳过括号以获得更好的性能：

sum(x[k]*base^(k-1) for k in 1:length(x))

这也在求和之前分配了一个数组：sum(d.*4 .^(0:(length(d)-1)))

不过，如果你真的想要好的性能，写一个循环并避免重复取幂：

function undigit(d; base=10)
    s = zero(eltype(d))
    mult = one(eltype(d))
    for val in d
        s += val * mult
        mult *= base
    end
    return s
end

这有一个额外的不必要的乘法，你可以试着想办法跳过它。但在我的测试中，性能比其他方法好 10-15 倍，并且分配为零。

编辑： 上述类型处理实际上存在轻微风险。如果输入向量和 base 具有不同的整数类型，则会出现类型不稳定性。这段代码应该表现得更好：

function undigits(d; base=10)
    (s, b) = promote(zero(eltype(d)), base)
    mult = one(s)
    for val in d
        s += val * mult
        mult *= b
    end
    return s
end

Answer 3

使用 foldr 和 muladd 以获得最大的简洁性和效率

undigits(d; base = 10) = foldr((a, b) -> muladd(base, b, a), d, init=0)

从数字数组中获取数字

Get a number from an array of digits

julia

base

digits