循环文件时数组元素被删除

Question

我在循环文件名时遇到问题，我的输入数组元素被删除了。

代码：

use Data::Dumper;
use warnings;
use strict;


my @files = ("file1", "file2", "file3");

print Dumper(\@files);

for (@files) {
        my $filename = $_ . '.txt';
        open(my $fh, '<:encoding(UTF-8)', $filename)
          or die "Could not open file '$filename' $!";
        while(<$fh>) {
                print "$filename read line \n";
        }
}
print Dumper(\@files);

输出：

$VAR1 = [
          'file1',
          'file2',
          'file3'
        ];
file1.txt read line
file2.txt read line
file3.txt read line
$VAR1 = [
          undef,
          undef,
          undef
        ];

文件内容：

 cat file1.txt
asdfsdfs
 cat file2.txt
iasdfasdsf
 cat file3.txt
sadflkjasdlfj

为什么数组内容被删除了？（我有 2 种不同的解决方法来解决这个问题，但我想了解这段代码有什么问题。）

Answer 1

您在循环内以两种不同的方式使用 $_（作为当前文件名和作为当前行），它们互相破坏。不要这样做。命名您的变量，例如：

for my $file (@files) {
    ...
    while(my $line = <$fh>) {
        ...
    }
}

您可以想象您当前的代码在读取每个文件后执行此操作：

for (@files) {
   undef $_;
}

Answer 2

while (<$fh>)

是

的缩写

while ($_ = <$fh>)

所以你正在破坏 $_，它是 @files 的一个元素的别名。您需要保护 $_ 如下：

while (local $_ = <$fh>)

更好的是，使用不同的变量名。

while (my $line = <$fh>)

循环文件时数组元素被删除

array elements gets deleted when looping files

perl

loops

file-handling