编写 运行 AutoLISP 文件的脚本

Question

我想使用 this lisp file 绘制大约 1000 个两个圆的切线形状，一次绘制一个形状。

我写了一个脚本来绘制所有形状（见下文），但是它在第一个参数之后等待下一个参数，尽管它在脚本中。

能否请您指导我如何修复我的脚本或如何编辑 lisp 文件，以便我可以在没有交互式输入的情况下绘制所有形状？

这是我当前的脚本：

ctan
0,0,0
5
0,10,0
10

Answer 1

问题是 Script 和 AutoLISP 函数的计算发生在同一个处理器线程中，因此当您从脚本文件中计算 AutoLISP 函数时，AutoLISP 函数将焦点从脚本，脚本文件的其余部分将在AutoLISP 函数完成其计算后进行计算。

为了解决这个问题，我建议定义一个单独的 AutoLISP 函数，它接受对应于每个圆的中心和半径的四个参数，并以与我的 Circle Tangents 相同的方式构造 2D LWPolyline申请。

然后您可以从您的脚本文件（如果需要，可能在多个绘图上）评估此类函数，或者从另一个 AutoLISP 程序中评估该函数。

这样的函数可能是：

(defun ctan ( c1 r1 c2 r2 / d1 d2 a1 a2 zv )
    (if (< (abs (setq d1 (- r1 r2))) (setq d2 (distance c1 c2)))
        (progn
            (setq a1 (atan (sqrt (- (* d2 d2) (* d1 d1))) d1)
                  a2 (angle c1 c2)
                  zv (trans '(0.0 0.0 1.0) 1 0 t)
            )
            (entmake
                (list
                   '(000 . "LWPOLYLINE")
                   '(100 . "AcDbEntity")
                   '(100 . "AcDbPolyline")
                   '(090 . 04)
                   '(070 . 01)
                    (cons 010 (trans (polar c1 (+ a1 a2) r1) 1 zv))
                    (cons 042 (/ (sin (/ (- pi a1) 2.0)) (cos (/ (- pi a1) 2.0))))
                    (cons 010 (trans (polar c1 (- a2 a1) r1) 1 zv))
                    (cons 010 (trans (polar c2 (- a2 a1) r2) 1 zv))
                    (cons 042 (/ (sin (/ a1 2.0)) (cos (/ a1 2.0))))
                    (cons 010 (trans (polar c2 (+ a1 a2) r2) 1 zv))
                    (cons 210 zv)
                )
            )
        )
    )
)

加载后，您可以使用脚本或其他 AutoLISP 程序调用：

(ctan '(0 0 0) 5 '(0 10 0) 10)