为什么函数的 return 语句不是通常的 int[ ]

Question

我刚开始使用 Dlang，它似乎非常适合想要更安全的 C 语言的人。此外，它还具有现代范例，例如函数式编程。

我正在尝试使用以下代码将数字列表作为字符串转换为整数列表：

import std.stdio; 
import std.array;
import std.conv;

int[] list_str2int(char[][] slist){     // this function should convert a list of numbers as char[] to integers
    int[100] intcol; 
    int N = cast(int)slist.length; 
    foreach(int i; 0..N){
        char[] temp = slist[i];
        temp = split(temp, ".")[0];   // effectively this is floor; to!int does not work if '.' is there; 
        intcol[i] = to!int(temp);   // not working; 
    }
    return intcol;                  // error from this statement; 
}

void main(){
    char[][] strlist = cast(char[][])["1.1","2.1","3.2","4.4"]; 
    int[] newintlist = list_str2int(strlist); 
    writeln("Converted list: ", newintlist); 
}

但出现以下错误：

testing.d(13): Error: returning cast(int[])intcol escapes a reference to local variable intcol
Failed: ["/usr/bin/dmd", "-v", "-o-", "testing.d", "-I."]

我不明白为什么变量是 int[] 的第一个函数的 return 行有错误。

问题出在哪里，如何解决？感谢您的帮助。

Answer 1

int[100] 是一个静态数组（值类型），并且位于 list_str2int 的堆栈帧上 - 因此一旦函数 returns 它就会不复存在。函数的 return 值 int[] 是一个切片（引用类型），它不包含任何数据，而是引用内存中某处的连续整数。语句 return intcol; 因此获取静态数组的一部分，但是 returning 它是无效的，因为该切片将指向在函数 returns 之后不再有效的内存。

您有几个选择：

也将 return 类型声明为 int[100]。使其成为值类型，整数将被复制到调用者的堆栈帧中。
通过将数组声明并初始化为 auto intcol = new int[100];，在程序的堆中分配数组。这将使 intcol 成为堆中的一片内存。堆中的内存由垃圾收集器拥有，并且实际上具有无限的生命周期。

与上述内容相去甚远但更符合现代 D 的选项是使用范围。您的程序可以重写为一条语句，如下所示：

import std.algorithm.iteration;
import std.stdio; 
import std.array;
import std.conv;

void main()
{
    ["1.1", "2.1", "3.2", "4.4"]
        .map!(item => item
            .split(".")[0]
            .to!int
        )
        .array // optional, writeln and co can write ranges
        .writefln!"Converted list: %s";
}

Answer 2

int[]是一个slice，可以动态分配。

int[100] 是一个包含 100 个元素的数组。它分配在堆栈上

就像在C中一样，你不能return函数中的本地内存，你不能return intcol，因为它后面的内存在函数之后变得无效returns.

我好像不知道，如果你想使用动态数组或静态。如果你想使用动态数组，那就坚持使用它们。

import std.stdio; 
import std.array;
import std.conv;

int[] list_str2int(char[][] slist){     // this function should convert a list of numbers as char[] to integers
    int N = cast(int)slist.length; 
    int[] intcol = new int[N];
    foreach(int i; 0..N){
        char[] temp = slist[i];
        temp = split(temp, ".")[0];   // effectively this is floor; to!int does not work if '.' is there; 
        intcol[i] = to!int(temp);   // not working; 
    }
    return intcol;                  // error from this statement; 
}

void main(){
    char[][] strlist = cast(char[][])["1.1","2.1","3.2","4.4"]; 
    int[] newintlist = list_str2int(strlist); 
    writeln("Converted list: ", newintlist); 
}

将输出：

 Converted list: [1, 2, 3, 4]

为什么函数的 return 语句不是通常的 int[ ]

Why function's return statement is not usual int[ ]

d