WillReturnDefault 有没有Spring4D对应的函数

Question

当你不关心函数的参数时，

Delphi-Mocks 有一个 WillReturnDefault 方法。我不知道如何使用 Spring4D mocking 来做到这一点。感谢您的帮助！

Answer 1

您可以在允许任何调用的默认动态模式下使用 mock，并且仅 returns 其方法的默认值，或者使用参数匹配器 - 请参见以下示例：

uses
  Spring.Mocking;

type
  {$M+}
  ITest = interface
    function GiveNumber(const s: string): Integer;
  end;

var
  m: Mock<ITest>;
begin
  // mocks are dynamic by default so they let all calls happen and return the default
  Writeln(m.Instance.GiveNumber(''));

  // parameter matcher can be either applied to the When call -
  // here we are using the built-in Args.Any to let any parameter happen
  // the actual values passed to GiveNumber does not matter then
  m.Setup.Returns(42).When(Args.Any).GiveNumber('');
  Writeln(m.Instance.GiveNumber('whatever'));

  // when specifying a specific param matcher you basically add this to the existing behavior
  // when calling the mock checks for any given behavior that matches starting from the
  // most recently defined
  m.Setup.Returns(77).When.GiveNumber(Arg.IsEqual('this'));
  Writeln(m.Instance.GiveNumber('this')); // 77 as we just specified
  Writeln(m.Instance.GiveNumber('something')); // 42 as we specified before for any arguments

  // so you should always start with the broader matcher and then the more specific ones
  // as a broader one would "override" a more specific one as you can see now
  m.Setup.Returns(42).When(Args.Any).GiveNumber('');
  // we get 42 now as the Args.Any matcher was added last and matches the parameter
  Writeln(m.Instance.GiveNumber('this'));

  Readln;
end.

WillReturnDefault 有没有Spring4D对应的函数

Is there a Spring4D correspondent function to WillReturnDefault

delphi

spring4d

delphi-mocks