在 JULIA 的分布式 for 循环中写入共享数组

Question

我有一个 ODE 需要求解各种参数。之前我使用MATLAB的parfor来划分多个线程之间的参数范围。我是 Julia 的新手，现在需要在 Julia 中做同样的事情。这是我正在使用的代码

using DifferentialEquations, SharedArrays, Distributed, Plots


function SingleBubble(du,u,p,t)
    du[1]=@. u[2]
    du[2]=@. ((-0.5*u[2]^2)*(3-u[2]/(p[4]))+(1+(1-3*p[7])*u[2]/p[4])*((p[6]-p[5])/p[2]+2*p[1]/(p[2]*p[8]))*(p[8]/u[1])^(3*p[7])-2*p[1]/(p[2]*u[1])-4*p[3]*u[2]/(p[2]*u[1])-(1+u[2]/p[4])*(p[6]-p[5]+p[10]*sin(2*pi*p[9]*t))/p[2]-p[10]*u[1]*cos(2*pi*p[9]*t)*2*pi*p[9]/(p[2]*p[4]))/((1-u[2]/p[4])*u[1]+4*p[3]/(p[2]*p[4]))
end

R0=2e-6
f=2e6
u0=[R0,0]
LN=1000

RS = SharedArray(zeros(LN))
P = SharedArray(zeros(LN))
bif = SharedArray(zeros(LN,6))

 @distributed     for i= 1:LN
    ps=1e3+i*1e3
    tspan=(0,60/f)
    p=[0.0725,998,1e-3,1481,0,1.01e5,7/5,R0,f,ps]
    prob = ODEProblem(SingleBubble,u0,tspan,p)
    sol=solve(prob,Tsit5(),alg_hints=:stiff,saveat=0.01/f,reltol=1e-8,abstol=1e-8)
    RS[i]=maximum((sol[1,5000:6000])/R0)
    P[i]=ps
    for j=1:6
          nn=5500+(j-1)*100;
          bif[i,j]=(sol[1,nn]/R0);
     end
end


plotly()
scatter(P/1e3,bif,shape=:circle,ms=0.5,label="")#,ma=0.6,mc=:black,mz=1,label="")

当使用一个 worker 时，for 循环基本上作为一个普通的单线程循环执行，并且工作正常。但是，当我使用 addprocs(n) 添加 n 个工人时，没有任何内容写入 SharedArrays RS、P 和 bif。我感谢任何人提供的任何指导。

Answer 1

需要进行这些更改才能使您的程序与多个工作人员一起工作并显示您需要的结果：

在 @distributed 循环下使用的任何包和函数都必须在使用 @everywhere 的所有进程中可用，如 here 所述。因此，在您的情况下，它将是 DifferentialEquations 和 SharedArrays 包以及 SingleBubble() 函数。
所有的工人都完成任务后才需要画图。为此，您需要使用 @sync 和 @distributed.

进行这些更改后，您的代码将如下所示：

using Distributed, Plots

@everywhere using DifferentialEquations, SharedArrays

@everywhere function SingleBubble(du,u,p,t)
    du[1]=@. u[2]
    du[2]=@. ((-0.5*u[2]^2)*(3-u[2]/(p[4]))+(1+(1-3*p[7])*u[2]/p[4])*((p[6]-p[5])/p[2]+2*p[1]/(p[2]*p[8]))*(p[8]/u[1])^(3*p[7])-2*p[1]/(p[2]*u[1])-4*p[3]*u[2]/(p[2]*u[1])-(1+u[2]/p[4])*(p[6]-p[5]+p[10]*sin(2*pi*p[9]*t))/p[2]-p[10]*u[1]*cos(2*pi*p[9]*t)*2*pi*p[9]/(p[2]*p[4]))/((1-u[2]/p[4])*u[1]+4*p[3]/(p[2]*p[4]))
end

R0=2e-6
f=2e6
u0=[R0,0]
LN=1000

RS = SharedArray(zeros(LN))
P = SharedArray(zeros(LN))
bif = SharedArray(zeros(LN,6))

@sync @distributed     for i= 1:LN
    ps=1e3+i*1e3
    tspan=(0,60/f)
    p=[0.0725,998,1e-3,1481,0,1.01e5,7/5,R0,f,ps]
    prob = ODEProblem(SingleBubble,u0,tspan,p)
    sol=solve(prob,Tsit5(),alg_hints=:stiff,saveat=0.01/f,reltol=1e-8,abstol=1e-8)
    RS[i]=maximum((sol[1,5000:6000])/R0)
    P[i]=ps
    for j=1:6
          nn=5500+(j-1)*100;
          bif[i,j]=(sol[1,nn]/R0);
     end
end


plotly()
scatter(P/1e3,bif,shape=:circle,ms=0.5,label="")#,ma=0.6,mc=:black,mz=1,label="")

使用多个 worker 的输出：

在 JULIA 的分布式 for 循环中写入共享数组

writing into shared arrays within a distributed for loop in JULIA

julia

differential-equations

plots.jl

differentialequations.jl