如何在 MQL5 中打印多维数组的值？

Question

在 MQL4 中，我可以使用以下函数打印二维数组中的值：

string Arr2ToString(double& arr[][], string dlm = ",", int digits = 2) {
  string res = "";
  int i, j;
  for (i = 0; i < ArrayRange(arr, 0); i++) {
    res += "[";
    for (j = 0; j < ArrayRange(arr, 1); j++) {
      res += StringFormat("%g%s", NormalizeDouble(arr[i][j], digits), dlm);
    }
    res = StringSubstr(res, 0, StringLen(res) - StringLen(dlm));
    res += "]" + dlm;
  }
  res = StringSubstr(res, 0, StringLen(res) - StringLen(dlm));
  return res;
}

但是在 MQL5（版本 5.00，内部版本 1966）中，上述函数不再有效，并且出现以下错误：

'[' - invalid index value Array.mqh

在传递arr[][]时的第一行。

我已经检查过，MQL5 不再允许传递没有维度大小的数组。

When passing multidimensional arrays to a function, dimension sizes (except for the first one) should be specified:
double var[][3][3];
void Func(double &arg[][3][3]){    // ... }

来源：MQL5 PROGRAMMING BASICS: ARRAYS.

这没有意义。

假设我不知道我的数组的大小（因为我想为多种数组类型重新使用这个函数，并且为每个大小定义几十个单独的函数是荒谬的），现在怎么可能打印存储双精度值的多维数组中的值（例如二维数组）？

Answer 1

我知道这并不理想，但我们可以使用 ArrayPrint() 来打印数组。 Refer here for the documentation

void  ArrayPrint( 
   const void&   array[],             // printed array 
   uint          digits=_Digits,      // number of decimal places 
   const string  separator=NULL,      // separator of the structure field values 
   ulong         start=0,             // first printed element index 
   ulong         count=WHOLE_ARRAY,   // number of printed elements 
   ulong         flags=ARRAYPRINT_HEADER|ARRAYPRINT_INDEX|ARRAYPRINT_LIMIT|ARRAYPRINT_ALIGN     
   );

这是将 multi-dimentional 数组传递给函数的另一种方法，同样也不理想，但它工作正常。

//+------------------------------------------------------------------+
//| Struct that is used to hold multi-dimentional array              |
//+------------------------------------------------------------------+
template<typename T>
struct MultiDimentionalArray
  {
   T                 index2[];      
  };
//+------------------------------------------------------------------+
//| Array print function that accepts MultiDimentionalArray struct   |
//+------------------------------------------------------------------+
string Arr2ToString(MultiDimentionalArray<double> &arr[],string dlm=",",int digits=2)
  {
   string res="";
   int i,j;
   for(i=0; i<ArraySize(arr); i++)
     {
      res+="[";
      for(j=0; j<ArraySize(arr[i].index2); j++)
        {
         res+=StringFormat("%g%s",NormalizeDouble(arr[i].index2[j],digits),dlm);
        }
      res = StringSubstr(res,0,StringLen(res) - StringLen(dlm));
      res+= "]" + dlm;
     }
   res=StringSubstr(res,0,StringLen(res)-StringLen(dlm));
   return res;
  }

这是一个执行示例

void OnStart()
  {
//--- Declaring an array
   MultiDimentionalArray<double> arr[];

//--- Adding values to the array
   for(int i=0;i<10;i++)
     {
      //--- Resizing the array - 1st dimention
      if(ArraySize(arr)<=i) ArrayResize(arr,ArraySize(arr)+1);

      for(int j=0;j<10;j++)
        {
         //--- Resizing the array - 2nd dimention
         if(ArraySize(arr[i].index2)<=j) ArrayResize(arr[i].index2,ArraySize(arr[i].index2)+1);
         arr[i].index2[j]=i*j;
        }
     }

//--- Getting the result as string
   string arrResult=Arr2ToString(arr);
//--- Printing the result string
   Print(arrResult);
  }

这是我在专家选项卡中通过执行上述代码得到的结果

2019.06.11 16:25:47.078 Arrays (EURUSD,H1)  [0,0,0,0,0,0,0,0,0,0],[0,1,2,3,4,5,6,7,8,9],[0,2,4,6,8,10,12,14,16,18],[0,3,6,9,12,15,18,21,24,27],[0,4,8,12,16,20,24,28,32,36],[0,5,10,15,20,25,30,35,40,45],[0,6,12,18,24,30,36,42,48,54],[0,7,14,21,28,35,42,49,56,63],[0,8,16,24,32,40,48,56,64,72],[0,9,18

如何在 MQL5 中打印多维数组的值？

How to print values from a multidimensional array in MQL5?

arrays

mql5