Terraform：将包含字符串列表的变量传递给 jsonencode 部分

Question

我想设置一个 Terraform 模块，根据 Terraforms policy assignment example 将策略分配给 Azure 资源。

为了分配允许的位置策略，我想将允许的位置列表作为字符串列表从 variables.tf 文件传递到执行分配的 main.tf。

main.tf

#Allowed Locations Policy Assignment 
resource "azurerm_policy_assignment" "allowedlocations" {
  name                 = "allowed-locations"
  scope                = var.scope_allowedlocations
  policy_definition_id = var.policy_allowedlocations.id 
  description          = "This policy enables you to restrict the locations."
  display_name         = "Allowed Locations"

  parameters = <<PARAMETERS
  {
  "allowedLocations": {
    "value": ${var.listofallowedlocations}
    }
  } 
  PARAMETERS

}

variables.tf

# Scope of the Allowed Locations policy
variable "scope_allowedlocations" {
  description = "The scope of the allowed locations assignment."
  default     = "Subscription"
}

# Scope of the Allowed Locations policy
variable "policy_allowedlocations" {
  description = "The allowed locations policy (created by the policy-define module)."
  default     = "default"
}

# List of the Allowed Locations
variable "listofallowedlocations" {
  type = list(string)
  description = "The allowed locations list."
  default     = [ "West Europe", "North Europe", "East US" ]
}

使用 terraform plan 执行会导致以下错误：

Error: Invalid template interpolation value

  on modules/policy-assign/main.tf line 16, in resource "azurerm_policy_assignment" "allowedlocations":
  12:
  13:
  14:
  15:
  16:     "value": ${var.listofallowedlocations}
  17:
  18:
  19:
    |----------------
    | var.listofallowedlocations is list of string with 3 elements

Cannot include the given value in a string template: string required.

因此，我不知道如何准确地将列表从变量文件传递到策略分配资源的参数部分。在 Terraforms policy assignment example 中，列表直接在 PARAMETERS 部分中进行内联编码并且有效。但是没有传递变量...:[=17=]

parameters = <<PARAMETERS
{
  "allowedLocations": {
    "value": [ "West Europe" ]
  }
}
PARAMETERS

Answer 1

当您将值插入字符串时，该值本身必须可转换为字符串，否则 Terraform 无法将各部分连接在一起以生成单个字符串结果。

这里有几个不同的选择，具有不同的权衡。

我个人在这里选择的选项是根本不使用 <<PARAMETERS 语法，而是使用 jsonencode:

构建整个值

parameters = jsonencode({
  allowedLocations = {
    value = var.listofallowedlocations
  }
})

这避免了您的配置需要处理任何 JSON 语法问题，并且（主观上）因此使意图更清晰，将来的维护更容易。

在结果是单个有效 JSON 值的任何情况下，我总是会选择使用 jsonencode 而不是模板语言。为了完整性，我在下面包括了其他选项，以防将来 reader 试图将集合值包含到不是生成 JSON 的字符串模板中.

第二种选择是编写一个表达式来告诉 Terraform 一种将列表值转换为合适格式的字符串值的方法。在你的情况下你想要 JSON 所以 jsonencode 可能是最合适的选择：

parameters = <<PARAMETERS
{
  "allowedLocations": {
    "value": ${jsonencode(var.listofallowedlocations)}
  }
} 
PARAMETERS

在其他非 JSON 情况下，当结果是一个简单的字符串列表时，join 函数可以用于将所有字符串与固定分隔符连接在一起。

Terraform's functions 中的任何一个产生单个字符串的结果都是这里的候选者。 "String Functions"和"Encoding Functions"下的是最有可能的选择。

最后，对于从集合值到结果字符串的映射是标准函数无法处理的自定义内容的情况，您可以使用模板重复语法：

parameters = <<CONFIG
%{ for port in var.ports ~}
listen 127.0.0.1:${port}
%{ endfor ~}
CONFIG

在这种情况下，Terraform 将为 var.ports 中的每个元素评估重复构造的主体一次，并将所有结果连接在一起以生成结果。您可以使用这种方法生成各种文本输出格式，但如果模板变得特别复杂，最好将其分解到一个单独的文件中并使用 templatefile 函数对其进行评估。

Terraform：将包含字符串列表的变量传递给 jsonencode 部分

Terraform: Pass a variable containing a list of strings to a jsonencode section

policy

json

variable-assignment

azure

terraform

main.tf

variables.tf