如何在 SQL 函数 CHARINDEX 中使用 RegEx 查找第 n 次出现

Question

以下算法的目的是从键中提取特定的字段集（在本例中，提取前 2 个字段），并且它有效。这些字段由冒号分隔：

declare @key nvarchar (max);
declare @pos int;
declare @fields nvarchar (max);

set @key = 'Field-1:Field-2:Field-3:Field-4:Field-5';
set @pos = charindex(':', @key, charindex (':', @key) + 1);
set @fields = left(@key, @pos - 1);

select @fields;

结果：Field-1:Field-2

Microsoft document 表示第一个参数是 表达式 ，但我认为在 CHARINDEX 的上下文中，它们的意思是，该表达式的计算结果应为字符串文字；因此，以下通过 RegEx 获取第二次出现的尝试不起作用；显然，要么它不受支持，要么我使用了错误的语法：

--match the second occurrence of the delimiter using RegEx
set @pos = charindex (':.*?(:)', @key);

换句话说，是否可以使用正则表达式找到给定文本中分隔符第n次出现的位置，从而避免嵌套CHARINDEX或循环解析？顺便说一句，如果 n 作为参数传递，那么我什至不能再使用静态嵌套了...

在此先感谢您的帮助。

环境：Microsoft SQL Server 2014 (SP3) 标准版（64 位）

Answer 1

提取字符串的第 n 个子字符串没有简单的方法，只有技巧。下面是一个基于集合的递归 CTE 方法：

DECLARE @str NVARCHAR(MAX) = N'Field-1:Field-2:Field-3:Field-4:Field-5';
DECLARE @num INT = 4;

WITH rcte AS (
    SELECT str = @str
         , n = 1
         , p = CHARINDEX(':', @str, 1)
    UNION ALL
    SELECT str
         , n + 1
         , CHARINDEX(':', str, p + 1)
    FROM rcte
    WHERE n < @num AND p > 0
)
SELECT CASE WHEN p > 0 THEN SUBSTRING(str, 1, p - 1) ELSE str END
FROM rcte
WHERE n = @num;

如果循环是一个选项，那么：

DECLARE @str NVARCHAR(MAX) = N'Field-1:Field-2:Field-3:Field-4:Field-5';
DECLARE @num INT = 4;
DECLARE @n INT = 0;
DECLARE @p INT = 0;

WHILE 1 = 1
BEGIN
    SET @n = @n + 1;
    SET @p = CHARINDEX(':', @str, @p + 1);
    IF @n = @num OR @p = 0 BREAK;
END;

SELECT CASE WHEN @p > 0 THEN SUBSTRING(@str, 1, @p - 1) ELSE @str END;

DB<>Fiddle

Answer 2

请注意，我在字符串末尾添加了“:”。请根据需要进行调整。

declare @n int = 5
declare @i int = 0
declare @len int = 0
declare @pos int = 0
declare @c char(1) = ":"
declare @str varchar(256)

set @str = "Field-1:Field-2:Field-3:Field-4:Field-5:"
set @len = len(@str)

while(@i < @n and @pos < @len)
begin
    set @pos = charindex(@c, @str, @pos + 1)
    set @i = @i + 1
end

select substring(@str, 1, @pos -1)

如何在 SQL 函数 CHARINDEX 中使用 RegEx 查找第 n 次出现

How to use RegEx in the SQL function CHARINDEX to find the nth occurrence

sql

sql-server

regex

sql-server-2014

charindex