在 FsCheck 中生成自定义数据

Question

我有一个 FsCheck 问题：
我有以下记录类型（我提前说，我被告知我的单例 DU 可能有点矫枉过正，但我发现它们描述了域，因此是必要的，除非必须，否则我不会删除它们）：

type Name = Name of string
type Quality = Quality of int
type ShelfLife = Days of int
type Style = Plain | Aged | Legendary

type Item = {
    Name: Name
    Quality: Quality
    ShelfLife: ShelfLife
    Style: Style
}

假设我已经定义了函数 repeat: Int -> ('a -> 'a) -> 'a 和 decreaseQuality: Item -> Item，我想编写一个 FsCheck 测试来检查不变量：Any item with style OTHER THAN 传奇，在 100 天过去后，质量为 0。

我的问题是我不知道以下关于 FsCheck 的事情：
1. 如何定义一个自定义生成器来生成非传奇风格的物品？相比之下，我如何定义 only 类型的 Legendary（以测试两种类型）？

我调查过：

 let itemGenerator = Arb.generate<Item>
 Gen.sample 80 5 itemGenerator

但这会创建非常奇怪的项目，因为 size 控制器，在示例中，80，还控制 Name of string 的长度（由于 of string）并且还会产生 Quality 和 ShelfLife 值，这些值对我的域来说是不可接受的（即负值），因为它们都被定义为 ... of int ，大小也由它控制。
（我也调查过 Gen.oneof...，但结果也是一个哑弹）。

即使假设我找到了生成自定义数据的方法，我如何定义仅测试记录质量属性的测试？

谢谢！

Answer 1

要始终生成有效的 Quality 和 ShelfLife，您需要注册任意实例：

type Arbs =
    static member Quality() =
        Arb.Default.NonNegativeInt()
        |> Arb.convert (fun (NonNegativeInt x) -> Quality x) (fun (Quality x) -> NonNegativeInt x)

    static member ShelfLife() =
        Arb.Default.NonNegativeInt()
        |> Arb.convert (fun (NonNegativeInt x) -> ShelfLife x) (fun (ShelfLife x) -> NonNegativeInt x)

Arb.register<Arbs>()

对于您想要检查的实际属性，这里有一个改写将有助于将其转换为 FsCheck：如果风格不是传奇，那么 100 天后质量为 0。在代码中：

let ``Non-legendary item breaks after 100 days`` (item: Item) =
    (item.Style <> Legendary) ==>
        let agedItem = item |> repeat 100 decreaseQuality
        agedItem.Quality = Quality 0

Answer 2

一旦您知道如何使用 gen { } 计算表达式以达到最大效果，您想要的大部分内容都会变得容易。

首先，我将解决如何生成非传奇的 Style。您可以使用 Gen.oneOf，但在这种情况下，我认为使用 Gen.elements 更简单，因为 oneOf 使用一系列 generators，但是elements 只需要一个项目列表并从该列表中生成一个项目。所以要生成一个非传奇的 Style，我会使用 Gen.elements [Plain; Aged]。（为了生成是传奇的 Style，我只是不使用生成器，只是将传奇分配给适当的记录字段，但稍后会详细介绍。）

至于名称太长，为了将生成的字符串的大小限制为最多 15 个字符，我会使用：

let genString15 = Gen.sized (fun s -> Gen.resize (min s 15) Arb.generate<string>)
// Note: "min" is not a typo. We want either s or 15, whichever is SMALLER
Gen.sample 80 5 genString15
// Never produces any strings longer than 15 characters

但这仍然可以生成 null 个字符串，所以我可能会在我的最终版本中使用它：

let genString15 =
    Gen.sized (fun s -> Gen.resize (min s 15) Arb.generate<NonNull<string>>)
    |> Gen.map (fun (NonNull x) -> x)  // Unwrap
Gen.sample 80 5 genString15
// Never produces any strings longer than 15 characters, AND never produces null

现在，由于 Quality 和 ShelfLife 都不能为负数，我会使用 PositiveInt（0 也不允许）或 NonNegativeInt（允许 0）。 FsCheck 文档中都没有详细记录，但它们的工作方式如下：

let x = Arb.generate<NonNegativeInt>
Gen.sample 80 5 x
// Produces [NonNegativeInt 79; NonNegativeInt 75; NonNegativeInt 0;
//           NonNegativeInt 69; NonNegativeInt 16] which is hard to deal with
let y = Arb.generate<NonNegativeInt> |> Gen.map (fun (NonNegativeInt n) -> n)
Gen.sample 80 5 y
// Much better: [79; 75; 0; 69; 16]

为了避免在 Quality 和 Days 的生成器之间重复代码，我将编写如下内容：

let genNonNegativeOf (f : int -> 'a) = gen {
    let! (NonNegativeInt n) = Arb.generate<NonNegativeInt>
    return (f n)
}
Gen.sample 80 5 (genNonNegativeOf Quality)
// Produces: [Quality 79; Quality 35; Quality 2; Quality 42; Quality 73]
Gen.sample 80 5 (genNonNegativeOf Days)
// Produces: [Days 60; Days 27; Days 50; Days 22; Days 23]

最后，让我们用 gen { } CE:

以一种漂亮、优雅的方式将它们结合在一起

let genNonLegendaryItem = gen {
    let! name = genString15 |> Gen.map Name
    let! quality = genNonNegativeOf Quality
    let! shelfLife = genNonNegativeOf Days
    let! style = Gen.elements [Plain; Aged]
    return {
        Name = name
        Quality = quality
        ShelfLife = shelfLife
        Style = style
    }
}
let genLegendaryItem =
    // This is the simplest way to avoid code duplication
    genNonLegendaryItem
    |> Gen.map (fun item -> { item with Style = Legendary })

然后一旦你完成了这个，要在你的测试中实际使用它，你需要注册生成器，正如 Tarmil 在他的回答中提到的那样。我可能会在这里使用单例 DU，以便于编写测试，如下所示：

type LegendaryItem = LegendaryItem of Item
type NonLegendaryItem = NonLegendaryItem of Item

然后您可以通过 Gen.map 将 genLegendaryItem 和 genNonLegendaryItem 生成器注册为生成 (Non)LegendaryItem 类型。然后您的测试用例将如下所示（我将在此处使用 Expecto 作为我的示例）：

[<Tests>]
let tests =
    testList "Item expiration" [
        testProperty "Non-legendary items expire after 100 days" <| fun (NonLegendaryItem item) ->
            let itemAfter100Days = item |> repeat 100 decreaseQuality
            itemAfter100Days.Quality = Quality 0
        testProperty "Legendary items never expire" <| fun (LegendaryItem item) ->
            let itemAfter100Days = item |> repeat 100 decreaseQuality
            itemAfter100Days.Quality > Quality 0
    ]

请注意，使用这种方法，您基本上必须自己编写收缩器，而按照 Tarmil 的建议使用 Arb.convert 会让您得到收缩器 "for free"。不要低估收缩器的价值，但如果你发现没有它们你也可以生活，我喜欢 gen { } 计算表达式的漂亮、干净的性质，以及阅读结果代码的容易程度。

Answer 3

在解决了我在理解 FsCheck 用法时遇到的所有问题（目前，我相信我将来会遇到更多问题），this is the repo 我的整个解决方案。

显然，测试代码位于（我认为恰当命名的）GildedRoseTests 文件夹中。

我使用了上面 rmunn 建议的 gen 计算表达式方法，但我做了一个不同的实验，使用 Tarmil 的 Arb 方法同样有效（而且你会缩小 "for free").

在 FsCheck 中生成自定义数据

Generating custom data in FsCheck

f#

fscheck