使用 movsb 从 VRAM 复制？

Question

在 x86 asm 中，在 VGA 模式 13 下从 VRAM 复制到数组变量的正确、快速的方法是什么？我可以使用 movsb 将 复制到 VRAM 没问题，但是使用 从 VRAM 复制 movsb 产生奇怪的结果，或者会使我的程序崩溃。

我有一个测试程序可以在 VRAM 中创建一行，将该行从 VRAM 复制到一个变量，然后将该变量复制到 VRAM 中的另一个位置。该程序无法按原样运行 - 奇怪地将 count dw 320 更改为 count equ 320 使其运行。知道我做错了什么吗？我不认为更改 count 变量是可行的解决方法。

; assemble with A86
jmp main

vdata db 320 dup 14
vdata_backup db 320 dup 0

video_memory equ 0a000h
count dw 320

wait_for_key:
        mov ax, 0h
        int 016h
        ret

main:
        ; set up mode 13
        mov ax, 013h
        int 10h

        ; copy some data to VRAM
        ; create a line on the screen
        mov si, offset vdata
        mov es, video_memory
        mov di, 640
        mov cx, count
        rep movsb

        ; copy from VRAM to vdata_backup
        push ds
        mov ds, video_memory
        mov si, 640
        mov es, code
        mov di, offset vdata_backup
        mov cx, count
        rep movsb
        pop ds

        ; copy vdata_backup to different part of VRAM
        ; create a new line on the screen
        mov si, offset vdata_backup
        mov es, video_memory
        mov di, 3200
        mov cx, count
        rep movsb

        call wait_for_key

        ; set back to text mode
        mov ah, 0
        mov al, 3
        int 10h

        ; exit to dos
        mov ah, 4ch
        int 21h

Answer 1

在代码部分 从 VRAM 复制到 vdata_backup 你做：

push ds
mov ds, video_memory 
[snip]
mov cx, count

您已更改 DS，使其指向视频图形段 A000。那不是 count 所在的段。 mov cx, count 隐式使用 DS 段，类似于 mov cx, [ds:count]。您从错误的内存位置检索了 count。简单的解决方法是在修改 DS 之前检索 count。代码可能如下所示：

push ds
mov cx, count
mov ds, video_memory 
[snip]