使用 for_each 创建的资源中带有 for_each 的动态块

Question

我正在尝试使用 Terraform 0.12+ 及其新的 for_each 和运行在 Azure 中构建多个 vnet 遇到了一些麻烦。我希望新功能能让我创建一个通用网络模块，它接受一个复杂的变量，但我可能已经达到了它的极限，或者只是没有正确地考虑它。本质上，我的变量构建方式类似于

variable "networks" {
  type = list(object({ name = string, newbits = number, netnum = number, subnets = list(object({ name = string, newbits = number, netnum = number}))}))
}

您可以看到它是一个网络数组，其中包含该网络的子网子数组。这样做可以轻松记录网络，而无需额外的 terraform 资源需求行，因此我们的网络团队可以轻松 adjust/expand 而无需担心了解 HCL。

我可以使用计数及其索引执行构建多个 vnet 资源的必要功能，但我想使用 for_each，因为它允许索引键而不是计数随着时间的推移而变化（需要重新部署，我们无法做到）。

网络对象

networks = [
    {
        # x.x.1.0/24
        name        = "DMZ",
        newbits     = "8",
        netnum      = "1",
        subnets      = [
            {
                # x.x.1.0/25
                name        = "DMZ"
                newbits     = "9",
                netnum      = "2"
            }
        ]
    },
    {
        # x.x.33.0/24
        name        = "Intermediary"
        newbits     = "8",
        netnum      = "33",
        subnets          = [
            {
                # x.x.33.0/25
                name        = "subnet1"
                newbits     = "9",
                netnum      = "66"
            },
            {
                # x.x.33.128/25
                name        = "subnet2"
                newbits     = "9",
                netnum      = "67"
            }
        ]
    }
]

我已经尝试并通过将对象更改为地图然后使用 each.key 和 each.value（为 each.value) 但问题在于创建子网。

locals {
    vnets = {
        for vnet in var.networks:
        vnet.name => cidrsubnet(var.root_cidr, vnet.newbits, vnet.netnum)
    }
}

由于地图不包括那些子网，所以我只是用头撞墙。有没有人有什么建议？还是我真的在不需要的时候把它弄得太复杂了？

有效的资源创建，但没有子网

resource "azurerm_virtual_network" "vnets" {
  for_each            = local.vnets
  name                = each.key
  address_space       = [each.value]
  location            = azurerm_resource_group.network.location
  resource_group_name = azurerm_resource_group.network.name
}

我希望我可以使用动态块并过滤它以匹配网络资源内部的 each.key。之后我也尝试用它自己的子网资源来做，但就是想不通。

这是我希望可以使用的全部资源

resource "azurerm_virtual_network" "vnets" {
  for_each            = local.vnets
  name                = "99999-Nucleus-${each.key}"
  address_space       = [each.value]
  location            = azurerm_resource_group.network.location
  resource_group_name = azurerm_resource_group.network.name

  dynamic "subnet" {
      for_each = [for vnet in var.networks:
      [for s in vnet.subnets: {
      name   = s.name
      prefix = cidrsubnet(var.root_cidr, s.newbits, s.netnum)
    }] if var.networks.name == each.key]

    content {
      name           = subnet.value.name
      address_prefix = subnet.value.prefix
    }
  }
}

Answer 1

在这里构建这个中间 local.vnets 映射使这个问题更难解决，因为它丢弃了那些对象中的所有其他信息，因此很难在 resource "azurerm_virtual_network" "vnets"块。

相反，如果我们对原始 var.networks 值使用重复，那么我们可以直接从 each.value:

中获得 subnets 列表

resource "azurerm_virtual_network" "vnets" {
  for_each = { for n in var.networks : n.name => n }

  location            = azurerm_resource_group.network.location
  resource_group_name = azurerm_resource_group.network.name

  name = "99999-Nucleus-${each.key}"
  address_space = [cidrsubnet(var.root_cidr, each.value.newbits, each.value.netnum)]

  dynamic "subnet" {
    for_each = each.value.subnets
    content {
      name           = subnet.value.name
      address_prefix = cidrsubnet(var.root_cidr, subnet.value.newbits, subnet.value.netnum)
    }
  }
}

使用 for_each 创建的资源中带有 for_each 的动态块

Dynamic block with for_each inside a resource created with a for_each

terraform

terraform0.12+