如何在 XSLT 中使用内联条件（if then else）？

Question

是否可以在 XSLT 中执行内联条件（if then else）？类似于：

<div id="{if blah then blah else that}"></div>

或者真实的use-case/example:

<div id="{if (@ID != '') then '@ID' else 'default'}"></div>

Answer 1

如评论中所述，if () then else 构造仅在 XSLT/XPpath 2.0 中受支持。

我自己的偏好是使用冗长但可读的：

<xsl:template match="some-node">
    <div> 
        <xsl:attribute name="ID">
            <xsl:choose>
                <xsl:when test="string(@ID)">
                    <xsl:value-of select="@ID"/>
                </xsl:when>
                <xsl:otherwise>default</xsl:otherwise>
            </xsl:choose>
        </xsl:attribute>
    </div>
</xsl:template>

或者更短：

<xsl:template match="some-node">
    <div ID="{@ID}"> 
        <xsl:if test="not(string(@ID))">
            <xsl:attribute name="ID">default</xsl:attribute>
        </xsl:if>
    </div>
</xsl:template>

但是，如果您喜欢神秘代码，您可能会喜欢：

<xsl:template match="some-node">
    <div ID="{substring(concat('default', @ID), 1 + 7 * boolean(string(@ID)))}"> 
    </div>
</xsl:template>

或：

<xsl:template match="some-node">
    <div ID="{concat(@ID, substring('default', 1, 7 * not(string(@ID))))}"> 
    </div>
</xsl:template>

如何在 XSLT 中使用内联条件（if then else）？

How to use inline conditional (if then else) in XSLT?

xslt

sharepoint

dataviewwebpart

xslt-1.0

sharepoint-2010