如何在 Arduino 中反转 FFT

Question

我正在尝试根据以下代码使用 Arduino FFT library 进行 FFT（快速傅里叶变换）

过滤一些数据

/*
fft_adc_serial.pde
guest openmusiclabs.com 7.7.14
example sketch for testing the fft library.
it takes in data on ADC0 (Analog0) and processes them
with the fft. the data is sent out over the serial
port at 115.2kb.
*/

#define LOG_OUT 1 // use the log output function
#define FFT_N 256 // set to 256 point fft

#include <FFT.h> // include the library

void setup() {
  Serial.begin(115200); // use the serial port
  TIMSK0 = 0; // turn off timer0 for lower jitter
  ADCSRA = 0xe5; // set the adc to free running mode
  ADMUX = 0x40; // use adc0
  DIDR0 = 0x01; // turn off the digital input for adc0
}

void loop() {
  while(1) { // reduces jitter
    cli();  // UDRE interrupt slows this way down on arduino1.0
    for (int i = 0 ; i < 512 ; i += 2) { // save 256 samples
      while(!(ADCSRA & 0x10)); // wait for adc to be ready
      ADCSRA = 0xf5; // restart adc
      byte m = ADCL; // fetch adc data
      byte j = ADCH;
      int k = (j << 8) | m; // form into an int

      k -= 0x0200; // form into a signed int
      k <<= 6; // form into a 16b signed int
      fft_input[i] = k; // put real data into even bins
     // Serial.print(millis());
     // Serial.print("input ");
     // Serial.print(i);
    //  Serial.print(" = ");
      Serial.println(k);
      fft_input[i+1] = 0; // set odd bins to 0
      delay(0.1);
    }
    fft_window(); // window the data for better frequency response
    fft_reorder(); // reorder the data before doing the fft
    fft_run(); // process the data in the fft
    fft_mag_log(); // take the output of the fft
    sei();
    Serial.println("start");

   for (byte i = 0; i < FFT_N/2; i++) {
     if(i<10 || i>20)
     {
       fft_log_out[i] = 0;
     }

     Serial.println(fft_log_out[i]);
   }    
  }
}

像这样应用过滤器后：

if(i<10 || i>20)
     {
       fft_log_out[i] = 0;
     }

然后我需要反 FFT 数据 fft_log_out[]。

我寻找了一个反 FFT 函数（特别是在 http://wiki.openmusiclabs.com/wiki/FFTFunctions 中）但是找不到它。

那么如何在 Arduino 中获得逆向 FFT？

Answer 1

逆FFT可以利用正变换得到：

for (int i = 0 ; i < 512 ; i += 2) {
  fft_input[i] =  (fft_input[i] >> 8);
  fft_input[i+1] = -(fft_input[i+1] >> 8);
}
fft_reorder();
fft_run();
// For complex data, you would then need to negate the imaginary part
// but we can skip this step since you have real data.

但请注意，您的过滤代码存在一些问题。

首先，前向FFT的结果是复数，同时携带幅度和相位信息。使用 fft_mag_log 仅取幅度，仅靠幅度不足以恢复原始信号。因此，您应该使用留在 fft_input 数组中的完整 FFT 输出作为过滤代码的输入。

其次，实值数据的 FFT 产生具有 Hermitian 对称性的频谱。要获得真正有价值的过滤输出，您必须保持这种对称性。因此，您不应该将频谱上半部分的值完全归零：

for (byte i = 0; i < FFT_N; i+=2) {
  if (! ((i>=20 && i<=40) || (i>=FFT_N-40 && i<=FFT_N-20)))
  {
    fft_input[i] = 0;
    fft_input[i+1] = 0;
  }
}

第三，过滤将彼此独立地应用于每个数据块，始终假设先前的输入为零。这通常会导致块边界处的不连续性。为避免这种情况，您应该考虑使用 overlap-add method.

如何在 Arduino 中反转 FFT

How to Inverse FFT in Arduino

arduino

fft

ifft