在不使用临时解析器实现的情况下反序列化许多网络消息

Question

我有一个关于反序列化的问题。我可以设想使用 Data.Data、Data.Typeable 或 GHC.Generics 的解决方案，但我很好奇它是否可以在没有泛型、SYB 或元编程的情况下实现。

问题描述：

已知 [String] 列表包含本地定义的代数数据类型的字段，我想反序列化 [String] 以构造目标数据类型。我可以编写一个解析器来执行此操作，但我正在寻找一种通用解决方案，该解决方案将反序列化为程序中定义的任意数量的数据类型，而无需为每种类型编写解析器。了解了代数类型所具有的值构造函数的数量和类型后，就像对每个字符串执行 read 以生成构建该类型所需的适当值一样简单。但是，我不想使用泛型、反射、SYB 或元编程（除非不可能）。

假设我定义了大约 50 种与此类似的类型（所有由基本基元组成的简单代数类型（没有嵌套或递归类型，只有基元的不同组合和排序）：

data NetworkMsg = NetworkMsg { field1 :: Int, field2 :: Int, field3 :: Double}

data NetworkMsg2 = NetworkMsg2 { field1 :: Double, field2 :: Int, field3 :: Double }

我可以使用在每个 [String] 之前解析的标记 ID 确定与我通过网络接收的 [String] 关联的数据类型。

可能的推测解路径：

由于数据构造函数是Haskell中的first-class值，并且实际上有一个类型--NetworkMsg构造函数是否可以被认为是一个函数，例如：

NetworkMsg :: Int -> Int -> Double -> NetworkMsg

我能否使用 uncurryN 将此函数转换为元组函数，然后将 [String] 复制到函数现在采用的相同形状的元组中？

NetworkMsg' :: (Int, Int, Double) -> NetworkMsg

我认为这行不通，因为我需要了解值构造函数和类型信息，这需要 Data.Typeable、反射或其他一些元编程技术。

基本上，我正在寻找许多类型的自动反序列化，而无需编写类型实例声明或在运行时分析类型的形状。如果不可行，我会用另一种方式来做。

Answer 1

你是对的，因为构造函数本质上只是函数，所以你可以通过为函数编写实例来为任意数量的类型编写泛型实例。您仍然需要编写一个单独的实例不过，对于所有不同数量的参数。

{-# LANGUAGE FlexibleInstances #-}
{-# LANGUAGE MultiParamTypeClasses #-}

import Text.Read
import Control.Applicative

class FieldParser p r where
    parseFields :: p -> [String] -> Maybe r

instance Read a => FieldParser (a -> r) r where
    parseFields con [a] = con <$> readMaybe a
    parseFields _ _ = Nothing

instance (Read a, Read b) => FieldParser (a -> b -> r) r where
    parseFields con [a, b] = con <$> readMaybe a <*> readMaybe b
    parseFields _ _ = Nothing

instance (Read a, Read b, Read c) => FieldParser (a -> b -> c -> r) r where
    parseFields con [a, b, c] = con <$> readMaybe a <*> readMaybe b <*> readMaybe c
    parseFields _ _ = Nothing

{- etc. for as many arguments as you need -}

现在您可以使用此类型 class 来解析基于构造函数的任何消息，只要类型检查器能够从上下文中找出结果消息类型（即它无法推断出它只是来自这些多参数类型 class 实例的给定构造函数。

data Test1 = Test1 {fieldA :: Int} deriving Show
data Test2 = Test2 {fieldB ::Int, fieldC :: Float} deriving Show

test :: String -> [String] -> IO ()
test tag fields = case tag of
    "Test1" -> case parseFields Test1 fields of
        Just (a :: Test1) -> putStrLn $ "Succesfully parsed " ++ show a
        Nothing -> putStrLn "Parse error"
    "Test2" -> case parseFields Test2 fields of
        Just (a :: Test2) -> putStrLn $ "Succesfully parsed " ++ show a
        Nothing -> putStrLn "Parse error"

不过，我想知道您在应用程序中究竟是如何使用消息类型的，因为将每条消息作为其单独的类型使得很难拥有任何类型的通用消息处理程序。

您为什么不只拥有单一消息数据类型是出于某种原因吗？如

data NetworkMsg
    = NetworkMsg1 {fieldA :: Int}
    | NetworkMsg2 {fieldB :: Int, fieldC :: Float}

现在，虽然实例的构建方式几乎相同，但您会得到更好的类型推断，因为结果类型始终是已知的。

instance Read a => MessageParser (a -> NetworkMsg) where
    parseMsg con [a] = con <$> readMaybe a

instance (Read a, Read b) => MessageParser (a -> b -> NetworkMsg) where
    parseMsg con [a, b] = con <$> readMaybe a <*> readMaybe b

instance (Read a, Read b, Read c) => MessageParser (a -> b -> c -> NetworkMsg) where
    parseMsg con [a, b, c] = con <$> readMaybe a <*> readMaybe b <*> readMaybe c

parseMessage :: String -> [String] -> Maybe NetworkMsg
parseMessage tag fields = case tag of
    "NetworkMsg1" -> parseMsg NetworkMsg1 fields
    "NetworkMsg2" -> parseMsg NetworkMsg2 fields
    _ -> Nothing

我也不确定为什么要专门进行类型泛型编程而不实际使用任何用于泛型的工具。 GHC.Generics、SYB 或 Template Haskell 通常是此类问题的最佳解决方案。

在不使用临时解析器实现的情况下反序列化许多网络消息

Deserializing many network messages without using an ad-hoc parser implementation

haskell

deserialization