模糊的边缘不断恢复 100% 的不透明度（处理中）

Question

我正在尝试通过以下代码在 Processing 中创建一个边缘模糊的圆刷。圆形是逐像素绘制的，因为在实际版本中，我尝试使用取自 PGraphic pg 的像素进行绘制。

PFont font;
PGraphics pg;
int X;
int Y;
int rad = 20;

void setup (){
    size(800, 800, P2D);
    background(0);
    noStroke();

    pg = createGraphics(800, 800, JAVA2D);
    pg.beginDraw();
    pg.fill(255);
    pg.noStroke();
    pg.textFont(font);
    pg.textSize(400);
    pg.pushMatrix();
    pg.translate(width/2, height/2-140);
    pg.textAlign(CENTER, CENTER);
    pg.text("b", 0 , 0);
    pg.popMatrix();
    pg.endDraw();
}

void draw () {
    image(pg,0,0);
}

void mousePressed(){
    X = mouseX;
    Y = mouseY;
}

void mouseDragged(){

    for (int x=0; x<rad; x++) {
        for (int y=0; y<rad; y++) {
        float distance = sqrt(pow(x,2)+pow(y,2));
        float alpha = 255-map(distance,0,rad,0,255);

            if (sqrt(pow(x,2)+pow(y,2)) < rad){
                pg.beginDraw();
                pg.set(mouseX+x,mouseY+y,color(255,255,255, alpha));
                pg.set(mouseX-x,mouseY+y,color(255,255,255, alpha));
                pg.set(mouseX+x,mouseY-y,color(255,255,255, alpha));
                pg.set(mouseX-x,mouseY-y,color(255,255,255, alpha));
                pg.endDraw();
            }
        }
    }
}

Answer 1

在你的绘图方法中的 "image(pg,0,0);" 之前添加一个 "background(0);" ，这样你每次都会重置背景，如果你不这样做，程序将继续在上面绘制每一帧图像彼此的，这将使低不透明度像素每帧缓慢增加不透明度，直到达到 100%

void draw () {
  background(0);
  image(pg,0,0);
}

编辑：测试你的代码后，我注意到你创建这些圆圈的方式有问题，使它变得非常慢运行（你通过双 for 循环绘制一个圆圈的每一帧）并且还给出了奇怪的黑色边缘问题，所以这就是我所做的：

首先我使用了你的变量 pg 并在启动时在其上画了一个圆圈，然后我声明了另一个 PGraphics 'pg_all'，我在每次调用 mousedrag 方法时画了一个 pg，我在多个背景上测试了它看起来工作正常，这是最终代码，如果您不理解某个部分或想做不同的事情，请告诉我：

PFont font;
PGraphics pg;
PGraphics pg_all;
int X;
int Y;
int rad = 20;

void setup (){
  size(800, 800, P2D);
  background(0);
  noStroke();

  pg_all = createGraphics(800, 800, JAVA2D);
  pg_all.beginDraw();
  pg_all.endDraw();

  pg = createGraphics(800, 800, JAVA2D);
  pg.beginDraw();
  for (int x=0; x<rad; x++) {
    for (int y=0; y<rad; y++) {
      float distance = sqrt(pow(x,2)+pow(y,2));
      float alpha = 255-map(distance,0,rad,0,255);

      if (sqrt(pow(x,2)+pow(y,2)) < rad){
        pg.beginDraw();
        pg.set(20+x,20+y,color(255,255,255, alpha));
        pg.set(20-x,20+y,color(255,255,255, alpha));
        pg.set(20+x,20-y,color(255,255,255, alpha));
        pg.set(20-x,20-y,color(255,255,255, alpha));
        pg.endDraw();
      }
    }
  }
  pg.endDraw();
}

void draw () {   
  background(0);
  image(pg_all,0,0); 
}

void mouseDragged(){
  X = mouseX;
  Y = mouseY;

  pg_all.beginDraw();
  pg_all.image(pg,X-rad,Y-rad);
  pg_all.endDraw();
}

Answer 2

创建一个将单个点绘制到 PGraphics 对象的函数：

void DrawPen(PGraphics pg, int cptX, int cptY, int r) {
    pg.beginDraw();
    for (int x = 0; x < r; ++x) {
        for (int y = 0; y < r; ++y) {
          float distance = sqrt(x*x + y*y);
          float alpha = 255-map(distance,0,r,0,255);
          if (distance < r) {
              pg.set(cptX+x,cptY+y,color(255,255,255, alpha));
              pg.set(cptX-x,cptY+y,color(255,255,255, alpha));
              pg.set(cptX+x,cptY-y,color(255,255,255, alpha));
              pg.set(cptX-x,cptY-y,color(255,255,255, alpha));
          }
        }
    }
    pg.endDraw();
}

在 setup

中的单独 PGraphics 对象上画一个点

PGraphics pg;
PGraphics pg_pen;
int rad = 20;

void setup (){
    size(800, 800, P2D);

    pg = createGraphics(800, 800, JAVA2D);
    pg.beginDraw();
    // [...]
    pg.endDraw();

    pg_pen = createGraphics(2*rad, 2*rad, JAVA2D);
    DrawPen(pg_pen, rad, rad, rad);
}

拖动鼠标时，将 pg_pen 混合到当前鼠标位置的公共 PGraphics 对象 (pg)：

void mouseDragged(){
    pg.beginDraw();
    pg.image(pg_pen, mouseX-rad, mouseY-rad);
    pg.endDraw();
}

为了寻求完整性 draw 功能：

void draw () {
    background(0); 
    image(pg,0,0);
}

[...] and tried to get the color from the white part to draw on the black part.

向 DrawPen 函数添加一个 color 参数并在绘制之前清除笔 PGraphics:

void DrawPen(PGraphics pg, int cptX, int cptY, int r, color c) {
    pg.beginDraw();
    pg.clear();
    for (int x = 0; x < r; ++x) {
        for (int y = 0; y < r; ++y) {
          float distance = sqrt(x*x + y*y);
          float alpha = 255-map(distance,0,r,0,255);
          if (distance < r) {
              color pc = color(red(c),green(c),blue(c), alpha);
              pg.set(cptX+x,cptY+y,pc);
              pg.set(cptX-x,cptY+y,pc);
              pg.set(cptX+x,cptY-y,pc);
              pg.set(cptX-x,cptY-y,pc);
          }
        }
    }
    pg.endDraw();
}

在鼠标按下事件回调中获取颜色并改变笔的颜色：

void mousePressed() {
    color c = pg.get(mouseX, mouseY);
    println(c);

    DrawPen(pg_pen, rad, rad, rad, c);
}

请注意，颜色是从 pg 对象中获取的，而不是从屏幕中获取的。如果你想从屏幕上获取颜色，那么它必须是（没有 .pg）：

color c = get(mouseX, mouseY);

此外，只要按下任何鼠标（按下而不是拖动），颜色就会随时改变。可能您想在按下鼠标右键时更改颜色并在按下鼠标左键时绘制：

void mousePressed() {
    if (mouseButton == RIGHT) {
        color c = pg.get(mouseX, mouseY);
        println(c);
        DrawPen(pg_pen, rad, rad, rad, c);
    }
}

模糊的边缘不断恢复 100% 的不透明度（处理中）

Blurred edges keep regaining 100% opacity (Processing)

java

processing

brush

blur

opacity