数组文字中不同大小的行 Google 张

Question

我正在尝试在 Google 表格中执行此操作：

={{1}; {1, 1}}

并得到错误 In ARRAY_LITERAL，Array Literal was missing values for a or more rows.

我的最终目标是做这样的事情：

"title A"
IMPORTRANGE("spreadsheet A", A:Z)...
"title B"
IMPORTRANGE("spreadsheet B", A:Z)...
"title C"
IMPORTRANGE("spreadsheet C", A:Z)...
etc...

导入范围最好也忽略空的 A 行。每个电子表格都有不同数量的列和行，它们每隔一段时间都会发生变化。

Answer 1

你需要这样做：

={{1, ""}; {1, 1}}

对于您的 IMPORTRANGE 示例，它将类似于：

={{"title A","","","","","","","","","","","","","","","","","","","","","","","","",""}; 
 IMPORTRANGE("ID", "Sheet1A:Z")}

但要避免重复空单元格，您可以这样做：

={{"title A", SUBSTITUTE(SPLIT(REPT(12, 25), 2), 1, )};
 IMPORTRANGE("ID", "Sheet1A:Z")}

这意味着：重复 (REPT) 数字 12 二十五次（因为你需要覆盖范围 B:Z）这将给你数字：12121212121212121212121212121212121212121212121212 现在你将 SPLIT 每次出现数字 2 时，您将在 25 个单元格中得到 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 。为了摆脱那些 1，你将 SUBSTITUTE 白白排名第一

或者像这样：

=ARRAYFORMULA({{"title A", SUBSTITUTE(COLUMN(B:Z)^0, 1, )};
 IMPORTRANGE("ID", "Sheet1A:Z")})

在尝试你的联合公式之前，也不要忘记每隔 IMPORTRANGE 分别运行。您需要允许访问才能将您的电子表格与每个唯一 IMPORTRANGE

={{"title A", SUBSTITUTE(SPLIT(REPT(12, 25), 2), 1, )};
 IMPORTRANGE("ID1", "Sheet1A:Z");
  {"title B", SUBSTITUTE(SPLIT(REPT(12, 25), 2), 1, )};
 IMPORTRANGE("ID2", "Sheet1A:Z");
  {"title C", SUBSTITUTE(SPLIT(REPT(12, 25), 2), 1, )};
 IMPORTRANGE("ID3", "Sheet1A:Z")}

要删除空行，您可以执行以下操作：

=QUERY({{"title A", SUBSTITUTE(SPLIT(REPT(12, 25), 2), 1, )};
        IMPORTRANGE("ID1", "Sheet1A:Z");
        {"title B", SUBSTITUTE(SPLIT(REPT(12, 25), 2), 1, )};
        IMPORTRANGE("ID2", "Sheet1A:Z");
        {"title C", SUBSTITUTE(SPLIT(REPT(12, 25), 2), 1, )};
        IMPORTRANGE("ID3", "Sheet1A:Z")}, 
 "where Col1 is not null", 0)

数组文字中不同大小的行 Google 张

Different size rows in array literal Google Sheets

arrays

google-sheets

google-sheets-query

importrange

google-sheets-formula