在宏定义宏中引用

Question

我正在尝试编写一个宏，为数组结构数据结构定义一些助手（基于 this 片段）。在该宏中，我定义了另一个宏，它有助于遍历结构中的所有槽值。问题是我无法使双重取消引用正常工作。这是代码：

(defmacro defcomponent (name-and-options &body slots)
  (setf name-and-options (ensure-list name-and-options))
  (let ((struct (first name-and-options))
        (slot-names (iter (for s in slots)
                          (collecting
                           (ematch s
                             ((or (and name (symbol)
                                       (<> _ '*)
                                       (<> _ nil))
                                  (list* name _ (plist :type _ :read-only _)))
                              name))))))
    `(progn (defstruct ,name-and-options
              ;; some task-specific stuff omitted here
              )
            (defmacro ,(symbolicate 'with- struct) (components &rest body)
              `(loop
                 ,@',(iter (for s in slot-names)
                          (appending `(for ,s across (,(symbolicate struct '- s) components))))
                 do ,@body)))))

例如 (defcomponent buzz x y) 宏扩展为

(PROGN
 (DEFSTRUCT (BUZZ)
   X Y)  ;; details omitted
 (DEFMACRO WITH-BUZZ (COMPONENTS &REST BODY)
   `(LOOP ,@'(FOR X ACROSS (BUZZ-X COMPONENTS) FOR Y ACROSS (BUZZ-Y COMPONENTS))
          DO ,@BODY))

哪个有点用，但我想访问内部 with-buzz 宏的 components 参数，即像这样的东西

(DEFMACRO WITH-BUZZ (COMPONENTS &REST BODY)
   `(LOOP FOR X ACROSS (BUZZ-X ,COMPONENTS) FOR Y ACROSS (BUZZ-Y ,COMPONENTS)
          DO ,@BODY))

我怎样才能做到这一点？我尝试了很多 , 和 ,@ 的组合都无济于事。

Answer 1

好吧，我通过手动构建列表 + eval 而不是准引用来做到这一点，但是天哪，它看起来太古怪了。

;; skip
(defmacro ,(symbolicate 'with- struct) (components &rest body)
    (append
    '(loop)
    (eval
    `(iter (for s in ',',slot-names)
            (appending `(for ,s across (,(symbolicate ',',struct '- ,'s) ,,components)))))
    '(do)
    body))

我很乐意接受任何其他更惯用地解决问题的答案。

Answer 2

有时不使用反引号模式会有所帮助。然后在编译器的帮助下可以更容易地理解范围问题，编译器会警告常见的变量范围问题。

作为一个稍微简化的练习，我们将编写一个生成代码的函数。生成的代码是一个宏定义，它自己生成代码。

(defun makeit (name slots)
  (labels ((symbolicate (pattern &rest things)
             (intern (apply #'format nil pattern things)))
           (compute-for-clauses (slots)
             (loop for s in slots
                   append (list ''for (list 'quote s)
                                ''across (list 'list
                                               (list 'quote
                                                     (symbolicate "~a-~a" name s))
                                               'components)))))

    (list 'progn
          (list 'defmacro
                (symbolicate "WITH-~a" name)
                '(components &rest body)
                (append '(list* 'loop)
                        (compute-for-clauses slots)
                        (list ''do 'body))))))

例子

CL-USER 51 > (pprint (makeit 'buzz '(x y)))

(PROGN
  (DEFMACRO WITH-BUZZ (COMPONENTS &REST BODY)
    (LIST* 'LOOP
           'FOR
           'X
           'ACROSS
           (LIST 'BUZZ-X COMPONENTS)
           'FOR
           'Y
           'ACROSS
           (LIST 'BUZZ-Y COMPONENTS)
           'DO
           BODY)))

CL-USER 52 > (eval *)
NIL

CL-USER 53 > (macroexpand-1 '(with-buzz a (+ 12) (+ 30)))
(LOOP FOR X ACROSS (BUZZ-X A) FOR Y ACROSS (BUZZ-Y A) DO (+ 12) (+ 30))
T

在宏定义宏中引用

Quoting in macro-defining macro

common-lisp

backquote

lisp-macros